FYI - Re: _LT_ENABLE_FAST_INSTALL being expanded multiple times.

[Peter O'Gorman]

Peter O'Gorman wrote:
> Hi,
> 
> When building ImageMagick on Mac OS X, and installing with DESTDIR
> Jochem Huhmann of the MacPorts project noticed that the wrapper scripts
> were being installed, and the binaries not.
> 
> I expect on darwin that fast_install always be set to needless,
> eliminating the need for relinking, however, with libtool HEAD, it gets
> set to needless, then if your configure.ac contains both LT_INIT and
> next LTDL_INIT, it gets set back to 'no' again.
> 
> Both LT_INIT and LTDL_INIT expand _LT_SET_OPTIONS, which duly expands
> _LT_ENABLE_FAST_INSTALL *twice*.
> 
> _LT_SET_OPTIONS should only set the default options once (and only for
> LT_INIT).
> 
> Peter

I committed this.

Peter
-- 
Peter O'Gorman
http://pogma.com

2008-02-06  Peter O'Gorman  <address@hidden>

        * libltdl/m4/ltoptions.m4 (_LT_SET_OPTIONS): Only set default
        LT_INIT values for LT_INIT, not LTDL_INIT.
        Reported by Jochem Huhmann <address@hidden> 

Index: libltdl/m4/ltoptions.m4
===================================================================
RCS file: /sources/libtool/libtool/libltdl/m4/ltoptions.m4,v
retrieving revision 1.11
diff -u -r1.11 ltoptions.m4
--- libltdl/m4/ltoptions.m4     14 Jan 2008 21:18:49 -0000      1.11
+++ libltdl/m4/ltoptions.m4     6 Feb 2008 19:52:48 -0000
@@ -62,23 +62,26 @@
 [# Set options
 m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
     [_LT_SET_OPTION([$1], _LT_Option)])
-dnl
-dnl Simply set some default values (i.e off) if boolean options were not
-dnl specified:
-_LT_UNLESS_OPTIONS([LT_INIT], [dlopen], [enable_dlopen=no
-])
-_LT_UNLESS_OPTIONS([LT_INIT], [win32-dll], [enable_win32_dll=no
-])
-dnl
-dnl If no reference was made to various pairs of opposing options, then
-dnl we run the default mode handler for the pair.  For example, if neither
-dnl `shared' nor `disable-shared' was passed, we enable building of shared
-dnl archives by default:
-_LT_UNLESS_OPTIONS([LT_INIT], [shared disable-shared], [_LT_ENABLE_SHARED])
-_LT_UNLESS_OPTIONS([LT_INIT], [static disable-static], [_LT_ENABLE_STATIC])
-_LT_UNLESS_OPTIONS([LT_INIT], [pic-only no-pic], [_LT_WITH_PIC])
-_LT_UNLESS_OPTIONS([LT_INIT], [fast-install disable-fast-install],
-                  [_LT_ENABLE_FAST_INSTALL])
+
+m4_if([$1],[LT_INIT],[
+  dnl
+  dnl Simply set some default values (i.e off) if boolean options were not
+  dnl specified:
+  _LT_UNLESS_OPTIONS([LT_INIT], [dlopen], [enable_dlopen=no
+  ])
+  _LT_UNLESS_OPTIONS([LT_INIT], [win32-dll], [enable_win32_dll=no
+  ])
+  dnl
+  dnl If no reference was made to various pairs of opposing options, then
+  dnl we run the default mode handler for the pair.  For example, if neither
+  dnl `shared' nor `disable-shared' was passed, we enable building of shared
+  dnl archives by default:
+  _LT_UNLESS_OPTIONS([LT_INIT], [shared disable-shared], [_LT_ENABLE_SHARED])
+  _LT_UNLESS_OPTIONS([LT_INIT], [static disable-static], [_LT_ENABLE_STATIC])
+  _LT_UNLESS_OPTIONS([LT_INIT], [pic-only no-pic], [_LT_WITH_PIC])
+  _LT_UNLESS_OPTIONS([LT_INIT], [fast-install disable-fast-install],
+                  [_LT_ENABLE_FAST_INSTALL])
+  ])
 ])# _LT_SET_OPTIONS