[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
02/04: emacs: Add "memoization" code.
From: |
Alex Kost |
Subject: |
02/04: emacs: Add "memoization" code. |
Date: |
Mon, 08 Jun 2015 08:51:44 +0000 |
alezost pushed a commit to branch master
in repository guix.
commit 132e74fec99eaf0febb62269ca38bacebeaa0882
Author: Alex Kost <address@hidden>
Date: Sat Jun 6 22:14:13 2015 +0300
emacs: Add "memoization" code.
* emacs/guix-utils.el (guix-memoize): New function.
(guix-memoized-defun): New macro.
---
emacs/guix-utils.el | 33 +++++++++++++++++++++++++++++++--
1 files changed, 31 insertions(+), 2 deletions(-)
diff --git a/emacs/guix-utils.el b/emacs/guix-utils.el
index 823c646..dc0c58a 100644
--- a/emacs/guix-utils.el
+++ b/emacs/guix-utils.el
@@ -1,6 +1,6 @@
-;;; guix-utils.el --- General utility functions
+;;; guix-utils.el --- General utility functions -*- lexical-binding: t -*-
-;; Copyright © 2014 Alex Kost <address@hidden>
+;; Copyright © 2014, 2015 Alex Kost <address@hidden>
;; This file is part of GNU Guix.
@@ -170,6 +170,35 @@ accessed with KEYS."
"Same as `diff', but use `guix-diff-switches' as default."
(diff old new (or switches guix-diff-switches) no-async))
+
+;;; Memoizing
+
+(defun guix-memoize (function)
+ "Return a memoized version of FUNCTION."
+ (let ((cache (make-hash-table :test 'equal)))
+ (lambda (&rest args)
+ (let ((result (gethash args cache 'not-found)))
+ (if (eq result 'not-found)
+ (let ((result (apply function args)))
+ (puthash args result cache)
+ result)
+ result)))))
+
+(defmacro guix-memoized-defun (name arglist docstring &rest body)
+ "Define a memoized function NAME.
+See `defun' for the meaning of arguments."
+ (declare (doc-string 3) (indent 2))
+ `(defalias ',name
+ (guix-memoize (lambda ,arglist ,@body))
+ ;; Add '(name args ...)' string with real arglist to the docstring,
+ ;; because *Help* will display '(name &rest ARGS)' for a defined
+ ;; function (since `guix-memoize' returns a lambda with '(&rest
+ ;; args)').
+ ,(format "(%S %s)\n\n%s"
+ name
+ (mapconcat #'symbol-name arglist " ")
+ docstring)))
+
(provide 'guix-utils)
;;; guix-utils.el ends here