[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
master 10573e0db7 1/6: ert-x: New `ert-with-test-buffer-selected' conven
From: |
Lars Ingebrigtsen |
Subject: |
master 10573e0db7 1/6: ert-x: New `ert-with-test-buffer-selected' convenience macro |
Date: |
Sun, 11 Sep 2022 07:46:36 -0400 (EDT) |
branch: master
commit 10573e0db7789f933a578d9a89d18b83a1cf6729
Author: Richard Hansen <rhansen@rhansen.org>
Commit: Lars Ingebrigtsen <larsi@gnus.org>
ert-x: New `ert-with-test-buffer-selected' convenience macro
* lisp/emacs-lisp/ert-x.el (ert-with-test-buffer-selected): New
convenience macro that extends `ert-with-test-buffer' by displaying
the test buffer in a temporary selected window. This makes it easier
to simulate user input in the body via `execute-kbd-macro'.
* test/lisp/emacs-lisp/ert-x-tests.el
(ert-test-test-buffer-selected/*): Add tests.
---
lisp/emacs-lisp/ert-x.el | 29 +++++++++++++++++++++++++++++
test/lisp/emacs-lisp/ert-x-tests.el | 15 +++++++++++++++
2 files changed, 44 insertions(+)
diff --git a/lisp/emacs-lisp/ert-x.el b/lisp/emacs-lisp/ert-x.el
index 4436d0a4b1..fe291290a2 100644
--- a/lisp/emacs-lisp/ert-x.el
+++ b/lisp/emacs-lisp/ert-x.el
@@ -102,6 +102,35 @@ the name of the test and the result of NAME-FORM."
(indent 1))
`(ert--call-with-test-buffer ,name-form (lambda () ,@body)))
+(cl-defmacro ert-with-test-buffer-selected ((&key name)
+ &body body)
+ "Create a test buffer, switch to it, and run BODY.
+
+This extends `ert-with-test-buffer' by displaying the test
+buffer (whose name is derived from NAME) in a temporary window.
+The temporary window becomes the `selected-window' before BODY is
+evaluated. The modification hooks `before-change-functions' and
+`after-change-functions' are not inhibited during the evaluation
+of BODY, which makes it easier to use `execute-kbd-macro' to
+simulate user interaction. The window configuration is restored
+before returning, even if BODY exits nonlocally. The return
+value is the last form in BODY."
+ (declare (debug ((":name" form) def-body))
+ (indent 1))
+ (let ((ret (make-symbol "ert--with-test-buffer-selected-ret")))
+ `(save-window-excursion
+ (let (,ret)
+ (ert-with-test-buffer (:name ,name)
+ (with-current-buffer-window (current-buffer)
+ `(display-buffer-below-selected
+ (body-function
+ . ,(lambda (window)
+ (select-window window t)
+ (let ((inhibit-modification-hooks nil))
+ (setq ,ret (progn ,@body))))))
+ nil))
+ ,ret))))
+
;;;###autoload
(defun ert-kill-all-test-buffers ()
"Kill all test buffers that are still live."
diff --git a/test/lisp/emacs-lisp/ert-x-tests.el
b/test/lisp/emacs-lisp/ert-x-tests.el
index 3869804110..63e7cd7608 100644
--- a/test/lisp/emacs-lisp/ert-x-tests.el
+++ b/test/lisp/emacs-lisp/ert-x-tests.el
@@ -82,6 +82,21 @@
(should-not (buffer-live-p buffer-1))
(should (buffer-live-p buffer-2))))))
+(ert-deftest ert-test-with-test-buffer-selected/selected ()
+ (ert-with-test-buffer-selected ()
+ (should (eq (window-buffer) (current-buffer)))))
+
+(ert-deftest ert-test-with-test-buffer-selected/modification-hooks ()
+ (ert-with-test-buffer-selected ()
+ (should (null inhibit-modification-hooks))))
+
+(ert-deftest ert-test-with-test-buffer-selected/return-value ()
+ (should (equal (ert-with-test-buffer-selected () "foo") "foo")))
+
+(ert-deftest ert-test-with-test-buffer-selected/buffer-name ()
+ (should (equal (ert-with-test-buffer (:name "foo") (buffer-name))
+ (ert-with-test-buffer-selected (:name "foo")
+ (buffer-name)))))
(ert-deftest ert-filter-string ()
(should (equal (ert-filter-string "foo bar baz" "quux")
- master updated (feffb03a36 -> f47a5324f4), Lars Ingebrigtsen, 2022/09/11
- master 99e8faa725 4/6: whitespace: Reset `whitespace-buffer-changed' when refontifying, Lars Ingebrigtsen, 2022/09/11
- master 395786f42b 5/6: whitespace: Include empty final line in BoB empty match, Lars Ingebrigtsen, 2022/09/11
- master 10573e0db7 1/6: ert-x: New `ert-with-test-buffer-selected' convenience macro,
Lars Ingebrigtsen <=
- master dd02725c57 3/6: ; whitespace: Use `defvar-local' for buffer-local vars, Lars Ingebrigtsen, 2022/09/11
- master b6da1e4221 2/6: ; whitespace: Delete unused `whitespace-font-lock-refontify' var, Lars Ingebrigtsen, 2022/09/11
- master f47a5324f4 6/6: whitespace: Redo BoB/EoB empty line highlighting, Lars Ingebrigtsen, 2022/09/11