fix/bug-48598 e0bf4383d7 24/27: Standardize auth-source queries in ERC

[F. Jason Park]

branch: fix/bug-48598
commit e0bf4383d7c4b93b0be1b2b5603f35bb594c1cd5
Author: F. Jason Park <jp@neverwas.me>
Commit: F. Jason Park <jp@neverwas.me>

    Standardize auth-source queries in ERC
    
    * lisp/erc/erc.el (erc-password): deprecate variable only used by
    `erc-select-read-args'.  Server passwords are primarily used as
    surrogates for other forms of authentication.  Such use is common but
    nonstandard and often discouraged in favor of the de facto standard,
    SASL.  Fans of invoking `erc(-tls)' interactively should be coerced
    into using auth-source instead.
    (erc-select-read-args): Before this change, `erc-select-read-args'
    offered to use the value of a non-nil `erc-password' as the :password
    argument for `erc' and `erc-tls', referring to it as the "default"
    password.  And when `erc-prompt-for-password' was nil and
    `erc-password' wasn't, the latter was passed along unconditionally.
    This only further complicated an already confusing situation for new
    users, who in most cases shouldn't be worried about sending a PASS
    command at all.  Until SASL arrives, they should provide server
    passwords manually or learn to use auth-source.
    (erc-auth-source-parameters-function): New user option to provide a
    function for determining the default params to use when calling
    `auth-source-search'.
    (erc--auth-source-determine-params): New helper for
    `erc--auth-source-search' with potential for wider role as default
    value of custom function.  Favors :host and :port fields above others.
    Prioritizes session IDs over announced servers and dialed endpoints.
    (erc--auth-source-search): New function for consulting auth-source and
    sorting result as per default params provided by above functions.
    (erc-server-join-channel): Use helper for consulting auth-source
    facility. Also accept nil for first argument (instead of server).  In
    this case, allow default params option above to determine best course
    of action.
    (erc-cmd-JOIN): use above-mentioned facilities when joining new
    channel.  Omit server when calling `erc-server-join-channel'.  Don't
    filter target buffers twice.  Don't call `switch-to-buffer', which
    would create phantom buffers with names like target/server that were
    never used.  IOW, only switch to existing target buffers.
    (erc-open, erc-determine-parameters, erc-compute-password): Move
    password figuring from former to latter, and from there to
    `erc-compute-password', which is a new function that figures out how
    to call `auth-source-search' based on the value of the new option
    `erc-connect-auth-source-host'.
    (erc-connect-auth-source-host): Add new option for customizing the
    :host param passed to `auth-source-search' while looking up the
    initial PASS arg.  The default setting preserves existing behavior of
    matching against the dialed host name or IP address stored in
    `erc-session-server'.  Other options allow skipping auth-source lookup
    altogether or favoring network ID, when non-nil.
    
    * lisp/erc/erc-services.el (erc-nickserv-get-password): pass network
    ID, i.e., effective session ID, when looking up password in
    `erc-nickserv-passwords' and when formatting prompt for user input.
    (erc-nickserv-passwords): add comment to custom option definition type
    tag.
    
    * test/lisp/erc/erc-services-tests.el: add new test file for above
    changes.  For now, also store auth-source-related tests belonging in
    erc-tests.el here.
    
    * lisp/erc/erc-join.el (erc-autojoin--join): Don't pass session-like
    entity from `erc-autojoin-alist' match to `erc-server-join-channel'.
    Allow that function to decide for itself which host to look up if
    necessary.
    
    * lisp/erc/erc-compat.el (erc-compat--auth-source-pass--couch,
    erc-compat--auth-source-pass--find-match,
    erc-compat--auth-source-pass--build-result,
    erc-compat--auth-source-pass-search,
    erc-compat--auth-source-pass-backend-parse): Add some adapters to make
    auth-source-pass behave more like netrc in ways ERC relies on.
---
 lisp/erc/erc-compat.el              |  86 +++++++++
 lisp/erc/erc-join.el                |   2 +-
 lisp/erc/erc-services.el            |  40 ++--
 lisp/erc/erc.el                     | 200 +++++++++++++++-----
 test/lisp/erc/erc-services-tests.el | 358 ++++++++++++++++++++++++++++++++++++
 5 files changed, 614 insertions(+), 72 deletions(-)

diff --git a/lisp/erc/erc-compat.el b/lisp/erc/erc-compat.el
index 16cfb15a5a..a833a61456 100644
--- a/lisp/erc/erc-compat.el
+++ b/lisp/erc/erc-compat.el
@@ -150,6 +150,92 @@ If START or END is negative, it counts from the end."
                 (setq i (1+ i) start (1+ start)))
               res))))))
 
+;;;; Auth Source
+
+;; We want a unified interface to auth-source, but that depends on
+;; upstream providing a consistent experience.  As of at least
+;;
+;;   lisp/auth-source-pass.el: Support multiple hosts in search
+;;   b09ee1406205e8b6298411b9a18c1cd26e201689 Fri Jul 2 2021
+;;
+;; auth-source-pass only returns singletons on success.  But we want
+;; all possible matches.  This provides some hacks to do that, but it
+;; depends on internal functions.  We also need to pass lists of
+;; candidates for host, user, and port selectors, which aren't yet
+;; fully supported.
+;;
+
+(require 'auth-source)
+
+(declare-function auth-source-pass--get-attr
+                  "auth-source-pass" (key entry-data))
+(declare-function auth-source-pass--disambiguate
+                  "auth-source-pass" (host &optional user port))
+(declare-function auth-source-pass--find-match-unambiguous
+                  "auth-source-pass" (hostname user port))
+(declare-function auth-source-backend-parse-parameters
+                  "auth-source-pass" (entry backend))
+
+(defun erc-compat--auth-source-pass--couch (s)
+  (lambda () (auth-source-pass--get-attr 'secret s)))
+
+(defun erc-compat--auth-source-pass--find-match (hosts ports users)
+  "Return a plist of HOSTS, PORTS, USERS, and secret.
+This is not a drop-in for `auth-source-pass--find-match', which
+returns an alist."
+  (unless (listp hosts) (setq hosts (list hosts)))
+  (unless (listp users) (setq users (list users)))
+  (unless (listp ports) (setq ports (list ports)))
+  ;; Try combinations of Hosts x Users x Ports, filter out nonexistent
+  (cl-loop for host in hosts
+           for (h u p) = (auth-source-pass--disambiguate host)
+           append
+           (cl-loop for user in (or users (list u))
+                    append
+                    (cl-loop for port in (or ports (list p))
+                             for s = (auth-source-pass--find-match-unambiguous
+                                      h user port)
+                             when s collect
+                             ;; Keep original host
+                             `(:host
+                               ,host
+                               ,@(and user (list :user user))
+                               ,@(and port (list :port port))
+                               :secret
+                               ,(erc-compat--auth-source-pass--couch s))))))
+
+(defun erc-compat--auth-source-pass--build-result (hosts ports users
+                                                         &optional max)
+  "Multi-valued `auth-source-pass--build-result'."
+  (unless max (setq max 1))
+  (let ((entries (erc-compat--auth-source-pass--find-match hosts ports users))
+        (count -1)
+        entry
+        out)
+    (while (and (setq entry (pop entries)) (< (cl-incf count) max))
+      (push entry out))
+    out))
+
+(cl-defun erc-compat--auth-source-pass-search
+    (&rest spec &key backend type host user port max &allow-other-keys)
+  (cl-assert (or (null type) (eq type (oref backend type)))
+             t "Invalid password-store search: %s %s")
+  (cl-assert (and host (not (eq host t)))
+             t "Invalid password-store search: %s %s")
+  (erc-compat--auth-source-pass--build-result host port user max))
+
+;; Temporary until we decide whether to load compat by default
+
+;;;###autoload
+(defun erc-compat--auth-source-pass-backend-parse (entry)
+  (when (eq entry 'password-store)
+    (auth-source-backend-parse-parameters
+     entry (auth-source-backend
+            :source "."
+            :type 'password-store
+            :search-function #'erc-compat--auth-source-pass-search))))
+
+
 (provide 'erc-compat)
 
 ;;; erc-compat.el ends here
diff --git a/lisp/erc/erc-join.el b/lisp/erc/erc-join.el
index fcfb961bff..b812dfc512 100644
--- a/lisp/erc/erc-join.el
+++ b/lisp/erc/erc-join.el
@@ -141,7 +141,7 @@ network or a session ID.  Return nil on failure."
         (let ((buf (erc-get-buffer chan erc-server-process)))
           (unless (and buf (with-current-buffer buf
                              (erc--current-buffer-joined-p)))
-            (erc-server-join-channel match chan)))))))
+            (erc-server-join-channel nil chan)))))))
 
 (defun erc-autojoin-after-ident (_network _nick)
   "Autojoin channels in `erc-autojoin-channels-alist'.
diff --git a/lisp/erc/erc-services.el b/lisp/erc/erc-services.el
index cc5d5701e4..f042a52250 100644
--- a/lisp/erc/erc-services.el
+++ b/lisp/erc/erc-services.el
@@ -202,7 +202,7 @@ Example of use:
                        (const QuakeNet)
                        (const Rizon)
                        (const SlashNET)
-                       (symbol :tag "Network name"))
+                        (symbol :tag "Network name or session ID"))
                (repeat :tag "Nickname and password"
                        (cons :tag "Identity"
                              (string :tag "Nick")
@@ -431,31 +431,19 @@ As soon as some source returns a password, the sequence of
 lookups stops and this function returns it (or returns nil if it
 is empty).  Otherwise, no corresponding password was found, and
 it returns nil."
-  (let (network server port)
-    ;; Fill in local vars, switching to the server buffer once only
-    (erc-with-server-buffer
-     (setq network erc-network
-           server erc-session-server
-           port erc-session-port))
-    (let ((ret
-           (or
-            (when erc-nickserv-passwords
-              (cdr (assoc nick
-                          (cl-second (assoc network
-                                            erc-nickserv-passwords)))))
-            (when erc-use-auth-source-for-nickserv-password
-              (auth-source-pick-first-password
-               :require '(:secret)
-               :host server
-               ;; Ensure a string for :port
-               :port (format "%s" port)
-               :user nick))
-            (when erc-prompt-for-nickserv-password
-              (read-passwd
-               (format "NickServ password for %s on %s (RET to cancel): "
-                       nick network))))))
-      (when (and ret (not (string= ret "")))
-        ret))))
+  (when-let*
+      ((esid (erc-networks--id-symbol erc-networks--id))
+       (ret (or (when erc-nickserv-passwords
+                  (assoc-default nick
+                                 (cadr (assq esid erc-nickserv-passwords))))
+                (when erc-use-auth-source-for-nickserv-password
+                  (erc--auth-source-search :user nick))
+                (when erc-prompt-for-nickserv-password
+                  (read-passwd
+                   (format "NickServ password for %s on %s (RET to cancel): "
+                           nick esid)))))
+       ((not (string-empty-p ret))))
+    ret))
 
 (defvar erc-auto-discard-away)
 
diff --git a/lisp/erc/erc.el b/lisp/erc/erc.el
index 230cfe456f..f25b2f2305 100644
--- a/lisp/erc/erc.el
+++ b/lisp/erc/erc.el
@@ -227,9 +227,14 @@ parameters and authentication."
                         "old behavior when t now permanent" "29.1")
 
 (defvar erc-password nil
-  "Password to use when authenticating to an IRC server.
-It is not strictly necessary to provide this, since ERC will
-prompt you for it.")
+  "Password to use when authenticating to an IRC server interactively.
+
+This variable only exists for legacy reasons.  It's not customizable and
+is limited to a single server password.  Users looking for similar
+functionality should consider auth-source instead.  See info
+node `(auth) Top' and info node `(erc) Connecting'.")
+
+(make-obsolete-variable 'erc-password "use auth-source instead" "29.1")
 
 (defcustom erc-user-mode "+i"
   ;; +i "Invisible".  Hides user from global /who and /names.
@@ -240,10 +245,32 @@ prompt you for it.")
 
 
 (defcustom erc-prompt-for-password t
-  "Asks before using the default password, or whether to enter a new one."
+  "Ask for a server password when invoking `erc-tls' interactively."
   :group 'erc
   :type 'boolean)
 
+(defcustom erc-connect-auth-source-host 'server
+  "Host \"type\" for querying auth-source when first connecting.
+This is for determining the \"server password\" argument of the IRC
+\"PASS\" command sent to the server.  The entry points `erc' and
+`erc-tls' query auth-source for such a password when a :password
+argument isn't provided.  Because ERC also interfaces with auth-source
+for other secrets, such as NickServ passwords and channel keys,
+additional ways of selecting entries are sometimes necessary.  See info
+node `(auth) Top'.
+
+Note that there aren't any options for specifying a network, like
+Libera.Chat, or a network-specific server, such as foo.libera.chat,
+because such information isn't available until after initial
+introductions have completed (\"registration\" in IRC speak)."
+  :package-version '(ERC . "5.4.1") ; FIXME increment upon publishing to ELPA
+  :group 'erc
+  :type '(choice (const :tag "Don't query auth-source" nil)
+                 (const :tag "Dialed host name or IP address" server)
+                 (const :tag "Prompt for a machine/host value" prompt)
+                 (const :tag "Session ID, if set, otherwise server" t)
+                 (string :tag "Literal value to use for :host")))
+
 (defcustom erc-warn-about-blank-lines t
   "Warn the user if they attempt to send a blank line."
   :group 'erc
@@ -2160,15 +2187,6 @@ Returns the buffer for the given server or channel."
     (setq erc-logged-in nil)
     ;; The local copy of `erc-nick' - the list of nicks to choose
     (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
-    ;; password stuff
-    (setq erc-session-password
-          (or passwd
-              (auth-source-pick-first-password
-               :host server
-               :user nick
-               ;; secrets.el wouldn’t accept a number
-               :port (if (numberp port) (number-to-string port) port)
-               :require '(:secret))))
     ;; client certificate (only useful if connecting over TLS)
     (setq erc-session-client-certificate client-certificate)
     (setq erc-networks--id (if connect
@@ -2190,7 +2208,7 @@ Returns the buffer for the given server or channel."
       (erc-display-prompt)
       (goto-char (point-max)))
 
-    (erc-determine-parameters server port nick full-name user)
+    (erc-determine-parameters server port nick full-name user passwd)
 
     ;; Saving log file on exit
     (run-hook-with-args 'erc-connect-pre-hook buffer)
@@ -2288,11 +2306,9 @@ parameters SERVER and NICK."
     (setq server user-input)
 
     (setq passwd (if erc-prompt-for-password
-                     (if (and erc-password
-                              (y-or-n-p "Use the default password? "))
-                         erc-password
-                       (read-passwd "Password: "))
-                   erc-password))
+                     (read-passwd "Server password: ")
+                   (with-suppressed-warnings ((obsolete erc-password))
+                     erc-password)))
     (when (and passwd (string= "" passwd))
       (setq passwd nil))
 
@@ -3305,18 +3321,104 @@ For a list of user commands (/join /part, ...):
 (defalias 'erc-cmd-H #'erc-cmd-HELP)
 (put 'erc-cmd-HELP 'process-not-needed t)
 
+(defcustom erc-auth-source-parameters-function
+  #'erc--auth-source-determine-params
+  "A function providing args to pass to `auth-source-search'.
+This is called with no arguments and should return a plist of keyword
+args accepted by `auth-source-search'.  The ordering of the pairs
+influences how results are filtered as does the ordering of the members
+of any composite pair values, when applicable.  If necessary, the former
+takes priority over the latter.  For example, if the function returns
+
+  (:host (foo bar) :port (123 456) :require (:secret))
+
+the secret from an auth-source entry of host foo and port 456
+will be chosen over another of host bar and port 123.  However,
+if the function returns
+
+  (:port (123 456) :host (foo bar) :require (:secret))
+
+the opposite will be true.  In both cases, two entries with the same
+host but different ports would see the one with port 123 being selected.
+Much the same would happen for entries sharing only a port: the one with
+host foo would win.
+
+Some auth-source back ends may not be compatible (netrc and pass are
+currently supported)."
+  :package-version '(ERC . "5.4.1") ; FIXME increment upon publishing to ELPA
+  :group 'erc
+  :type 'function)
+
+(defun erc--auth-source-determine-params ()
+  "Return a plist of default args to pass to `auth-source-search'.
+Favor a network ID over an announced server unless `erc--target' is a
+local channel.  Treat the dialed server address as a fallback for the
+announced name in both cases."
+  (let* ((net (and-let* ((esid (erc-networks--id-symbol erc-networks--id))
+                         ((symbol-name esid)))))
+         (localp (and erc--target (erc--target-channel-local-p erc--target)))
+         (hosts (if localp
+                    (list erc-server-announced-name erc-session-server net)
+                  (list net erc-server-announced-name erc-session-server)))
+         (ports (list (cl-typecase erc-session-port
+                        (integer (number-to-string erc-session-port))
+                        (string (and (string= erc-session-port "irc")
+                                     erc-session-port)) ; or nil
+                        (t erc-session-port))
+                      "irc")))
+    (list :host (delq nil hosts)
+          :port (delq nil ports)
+          :require '(:secret))))
+
+(declare-function erc-compat--auth-source-pass-backend-parse
+                  "erc-compat" (entry))
+
+(defun erc--auth-source-search (&rest plist)
+  "Ask auth-source for a secret and return it if found.
+Favor overrides in PLIST, if any.  Otherwise, use whatever's present in
+the list returned by `erc-auth-source-parameters-function'.  Return a
+string if found or nil otherwise."
+  (let* ((auth-source-backend-parser-functions
+          (if (memq 'password-store auth-sources)
+              (cons #'erc-compat--auth-source-pass-backend-parse
+                    auth-source-backend-parser-functions)
+            auth-source-backend-parser-functions))
+         (defaults (funcall erc-auth-source-parameters-function))
+         priority
+         (test (lambda (a b)
+                 (catch 'done
+                   (dolist (key priority)
+                     (let* ((d (plist-get defaults key))
+                            (default-value (if (listp d) d (list d)))
+                            ;; featurep 'seq via auth-source > json > map
+                            (p (seq-position default-value (plist-get a key)))
+                            (q (seq-position default-value (plist-get b key))))
+                       (unless (eql p q)
+                         (throw 'done (when p (or (not q) (< p q)))))))))))
+    (cl-loop for (key value) on defaults by #'cddr
+             when value unless (plist-get plist key)
+             do (setq plist (plist-put plist key value)))
+    (let ((keys (nreverse (map-keys defaults))))
+      (dolist (key (map-keys plist))
+        (cl-pushnew key keys))
+      (setq priority (nreverse keys)))
+    (unless (plist-get plist :max) ; from `auth-source-netrc-parse'
+      (setq plist (plist-put plist :max 5000)))
+    (when-let* ((sorted (sort (apply #'auth-source-search plist) test))
+                (secret (plist-get (car sorted) :secret)))
+      (if (functionp secret) (funcall secret) secret))))
+
 (defun erc-server-join-channel (server channel &optional secret)
-  (let ((password
-         (or secret
-             (auth-source-pick-first-password
-             :host server
-             :port "irc"
-             :user channel))))
-    (erc-log (format "cmd: JOIN: %s" channel))
-    (erc-server-send (concat "JOIN " channel
-                            (if password
-                                (concat " " password)
-                              "")))))
+  "Join CHANNEL, optionally with SECRET.
+Without SECRET, consult auth source, using SERVER if non-nil."
+  (unless secret
+    (unless server
+      (when (and erc-server-announced-name (erc-valid-local-channel-p channel))
+        (setq server erc-server-announced-name)))
+    (let ((args `(,@(when server (list :host server)) :user channel)))
+      (setq secret (apply #'erc--auth-source-search args))))
+  (erc-log (format "cmd: JOIN: %s" channel))
+  (erc-server-send (concat "JOIN " channel (when secret (concat " " secret)))))
 
 (defun erc-valid-local-channel-p (channel)
   "Non-nil when channel is server-local on a network that allows them."
@@ -3338,19 +3440,12 @@ were most recently invited.  See also `invitation'."
       (setq chnl (erc-ensure-channel-name channel)))
     (when chnl
       ;; Prevent double joining of same channel on same server.
-      (let* ((joined-channels
-              (mapcar (lambda (chanbuf)
-                        (with-current-buffer chanbuf (erc-default-target)))
-                      (erc-channel-list erc-server-process)))
-             (server (with-current-buffer (process-buffer erc-server-process)
-                      (or erc-session-server erc-server-announced-name)))
-             (chnl-name (car (erc-member-ignore-case chnl joined-channels))))
-        (if chnl-name
-            (switch-to-buffer (if (get-buffer chnl-name)
-                                  chnl-name
-                                (concat chnl-name "/" server)))
-          (setq erc--server-last-reconnect-count 0)
-         (erc-server-join-channel server chnl key)))))
+      (if-let* ((existing (erc-get-buffer chnl erc-server-process))
+                ((with-current-buffer existing
+                   (erc-get-channel-user (erc-current-nick)))))
+          (switch-to-buffer existing)
+        (setq erc--server-last-reconnect-count 0)
+        (erc-server-join-channel nil chnl key))))
   t)
 
 (defalias 'erc-cmd-CHANNEL #'erc-cmd-JOIN)
@@ -6305,7 +6400,7 @@ user input."
 
 ;; connection properties' heuristics
 
-(defun erc-determine-parameters (&optional server port nick name user)
+(defun erc-determine-parameters (&optional server port nick name user passwd)
   "Determine the connection and authentication parameters.
 Sets the buffer local variables:
 
@@ -6314,12 +6409,14 @@ Sets the buffer local variables:
 - `erc-session-port'
 - `erc-session-user-full-name'
 - `erc-session-username'
+- `erc-session-password'
 - `erc-server-current-nick'"
   (setq erc-session-connector erc-server-connect-function
         erc-session-server (erc-compute-server server)
         erc-session-port (or port erc-default-port)
         erc-session-user-full-name (erc-compute-full-name name)
-        erc-session-username (erc-compute-user user))
+        erc-session-username (erc-compute-user user)
+        erc-session-password (erc-compute-server-password passwd nick))
   (erc-set-current-nick (erc-compute-nick nick)))
 
 (defun erc-compute-server (&optional server)
@@ -6356,6 +6453,19 @@ non-nil value is found.
       (getenv "IRCNICK")
       (user-login-name)))
 
+(defun erc-compute-server-password (password nick)
+  "Determine initial PASSWORD value for IRC PASS command.
+Use the value of `erc-connect-auth-source-host' to determine the
+machine/host query param.  Use NICK for the user/login query param."
+  (or password
+      (when erc-connect-auth-source-host
+        (let* ((host (pcase erc-connect-auth-source-host
+                       ('server erc-session-server)
+                       ((and (pred stringp) v) v)
+                       ('prompt (read-string "Auth-source host: "
+                                             nil t (list nil)))))
+               (args `(,@(when host (list :host host)) :user ,nick)))
+          (apply #'erc--auth-source-search args)))))
 
 (defun erc-compute-full-name (&optional full-name)
   "Return user's full name.
diff --git a/test/lisp/erc/erc-services-tests.el 
b/test/lisp/erc/erc-services-tests.el
new file mode 100644
index 0000000000..f954d4a77e
--- /dev/null
+++ b/test/lisp/erc/erc-services-tests.el
@@ -0,0 +1,358 @@
+;;; erc-services-tests.el --- Tests for erc-services.  -*- lexical-binding:t 
-*-
+
+;; Copyright (C) 2020-2021 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+;;
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published
+;; by the Free Software Foundation, either version 3 of the License,
+;; or (at your option) any later version.
+;;
+;; GNU Emacs is distributed in the hope that it will be useful, but
+;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+;; General Public License for more details.
+;;
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; For convenience, some tests involving core auth-source
+;; functionality have been stashed here for the time being.
+
+;;; Code:
+
+(require 'ert-x)
+(require 'erc-services)
+(require 'erc-compat)
+
+;;;; Core auth-source
+
+;; Some of the following may be related to bug#23438.
+
+(defvar erc-join-tests--auth-source-entries
+  '("machine irc.gnu.org port irc user \"#chan\" password bar"
+    "machine my.gnu.org port irc user \"#chan\" password baz"
+    "machine GNU.chat port irc user \"#chan\" password foo"))
+
+(defun erc-services-tests--auth-source-shuffle (&rest extra)
+  (string-join `(,@(sort (append erc-join-tests--auth-source-entries extra)
+                         (lambda (&rest _) (zerop (random 2))))
+                 "")
+               "\n"))
+
+(ert-deftest erc--auth-source-search--standard ()
+  (ert-with-temp-file netrc-file
+    :prefix "erc--auth-source-search--standard"
+    :text (erc-services-tests--auth-source-shuffle)
+    (let ((auth-sources (list netrc-file))
+          (auth-source-do-cache nil))
+
+      (ert-info ("Normal ordering")
+
+        (ert-info ("Session wins")
+          (let ((erc-session-server "irc.gnu.org")
+                (erc-server-announced-name "my.gnu.org")
+                (erc-session-port 6697)
+                (erc-network 'fake)
+                (erc-server-current-nick "tester")
+                (erc-networks--id (erc-networks--id-create 'GNU.chat)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "foo"))))
+
+        (ert-info ("Network wins")
+          (let* ((erc-session-server "irc.gnu.org")
+                 (erc-server-announced-name "my.gnu.org")
+                 (erc-session-port 6697)
+                 (erc-network 'GNU.chat)
+                 (erc-server-current-nick "tester")
+                 (erc-networks--id (erc-networks--id-create nil)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "foo"))))
+
+        (ert-info ("Announced wins")
+          (let ((erc-session-server "irc.gnu.org")
+                (erc-server-announced-name "my.gnu.org")
+                (erc-session-port 6697)
+                erc-network
+                (erc-networks--id (erc-networks--id-create nil)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "baz"))))))))
+
+(ert-deftest erc--auth-source-search--announced ()
+  (ert-with-temp-file netrc-file
+    :prefix "erc--auth-source-search--announced"
+    :text (erc-services-tests--auth-source-shuffle)
+    (let* ((auth-sources (list netrc-file))
+           (auth-source-do-cache nil)
+           (erc--isupport-params (make-hash-table))
+           (erc-server-parameters '(("CHANTYPES" . "&#")))
+           (erc--target (erc--target-from-string "&chan")))
+
+      (ert-info ("Announced prioritized")
+
+        (ert-info ("Announced wins")
+          (let* ((erc-session-server "irc.gnu.org")
+                 (erc-server-announced-name "my.gnu.org")
+                 (erc-session-port 6697)
+                 (erc-network 'GNU.chat)
+                 (erc-server-current-nick "tester")
+                 (erc-networks--id (erc-networks--id-create nil)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "baz"))))
+
+        (ert-info ("Peer next")
+          (let* ((erc-server-announced-name "irc.gnu.org")
+                 (erc-session-port 6697)
+                 (erc-network 'GNU.chat)
+                 (erc-server-current-nick "tester")
+                 (erc-networks--id (erc-networks--id-create nil)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "bar"))))
+
+        (ert-info ("Network used as fallback")
+          (let* ((erc-session-port 6697)
+                 (erc-network 'GNU.chat)
+                 (erc-server-current-nick "tester")
+                 (erc-networks--id (erc-networks--id-create nil)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "foo"))))))))
+
+(ert-deftest erc--auth-source-search--overrides ()
+  (ert-with-temp-file netrc-file
+    :prefix "erc--auth-source-search--overrides"
+    :text (erc-services-tests--auth-source-shuffle
+           "machine GNU.chat port 6697 user \"#chan\" password spam"
+           "machine my.gnu.org port irc user \"#fsf\" password 42"
+           "machine irc.gnu.org port 6667 password sesame"
+           "machine MyHost port irc password 456"
+           "machine MyHost port 6667 password 123")
+
+    (let* ((auth-sources (list netrc-file))
+           (auth-source-do-cache nil)
+           (erc-session-server "irc.gnu.org")
+           (erc-server-announced-name "my.gnu.org")
+           (erc-network 'GNU.chat)
+           (erc-server-current-nick "tester")
+           (erc-networks--id (erc-networks--id-create nil))
+           (erc-session-port 6667))
+
+      (ert-info ("Specificity and overrides")
+
+        (ert-info ("More specific port")
+          (let ((erc-session-port 6697))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "spam"))))
+
+        (ert-info ("More specific user (network loses)")
+          (should (string= (erc--auth-source-search :user '("#fsf"))
+                           "42")))
+
+        (ert-info ("Actual override")
+          (should (string= (erc--auth-source-search :port "6667")
+                           "sesame")))
+
+        (ert-info ("Overrides don't interfere with post-processing")
+          (should (string= (erc--auth-source-search :host "MyHost")
+                           "123")))))))
+
+;; auth-source-pass backend
+
+(require 'auth-source-pass)
+
+;; `auth-source-pass--find-match-unambiguous' returns something like:
+;;
+;;   (list :host "irc.gnu.org"
+;;         :port "6697"
+;;         :user "rms"
+;;         :secret
+;;         #[0 "\301\302\300\"\207"
+;;             [((secret . "freedom")) auth-source-pass--get-attr secret] 3])
+;;
+;; This function gives ^ (faked here to avoid gpg and file IO).  See
+;; `auth-source-pass--with-store' in ../auth-source-pass-tests.el
+(defun erc-services-tests--asp-parse-entry (store entry)
+  (when-let ((found (cl-find entry store :key #'car :test #'string=)))
+    (list (assoc 'secret (cdr found)))))
+
+(defvar erc-join-tests--auth-source-pass-entries
+  '(("irc.gnu.org:irc/#chan"
+     ("port" . "irc") ("user" . "#chan") (secret . "bar"))
+    ("my.gnu.org:irc/#chan"
+     ("port" . "irc") ("user" . "#chan") (secret . "baz"))
+    ("GNU.chat:irc/#chan"
+     ("port" . "irc") ("user" . "#chan") (secret . "foo"))))
+
+(ert-deftest erc-services-tests--auth-source-pass--standard ()
+  (let ((store erc-join-tests--auth-source-pass-entries)
+        (auth-sources '(password-store))
+        (auth-source-do-cache nil))
+
+    (cl-letf (((symbol-function 'auth-source-pass-parse-entry)
+               (apply-partially #'erc-services-tests--asp-parse-entry store))
+              ((symbol-function 'auth-source-pass-entries)
+               (lambda () (mapcar #'car store))))
+
+      (ert-info ("Normal ordering")
+
+        (ert-info ("Session wins")
+          (let ((erc-session-server "irc.gnu.org")
+                (erc-server-announced-name "my.gnu.org")
+                (erc-session-port 6697)
+                (erc-network 'fake)
+                (erc-server-current-nick "tester")
+                (erc-networks--id (erc-networks--id-create 'GNU.chat)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "foo"))))
+
+        (ert-info ("Network wins")
+          (let* ((erc-session-server "irc.gnu.org")
+                 (erc-server-announced-name "my.gnu.org")
+                 (erc-session-port 6697)
+                 (erc-network 'GNU.chat)
+                 (erc-server-current-nick "tester")
+                 (erc-networks--id (erc-networks--id-create nil)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "foo"))))
+
+        (ert-info ("Announced wins")
+          (let ((erc-session-server "irc.gnu.org")
+                (erc-server-announced-name "my.gnu.org")
+                (erc-session-port 6697)
+                erc-network
+                (erc-networks--id (erc-networks--id-create nil)))
+            (should (string= (erc--auth-source-search :user "#chan")
+                             "baz"))))))))
+
+(ert-deftest erc-services-tests--auth-source-pass--announced ()
+  (let ((store erc-join-tests--auth-source-pass-entries)
+        (auth-sources '(password-store))
+        (auth-source-do-cache nil))
+
+    (cl-letf (((symbol-function 'auth-source-pass-parse-entry)
+               (apply-partially #'erc-services-tests--asp-parse-entry store))
+              ((symbol-function 'auth-source-pass-entries)
+               (lambda () (mapcar #'car store))))
+
+      (let* ((erc--isupport-params (make-hash-table))
+             (erc-server-parameters '(("CHANTYPES" . "&#")))
+             (erc--target (erc--target-from-string "&chan")))
+
+        (ert-info ("Announced prioritized")
+
+          (ert-info ("Announced wins")
+            (let* ((erc-session-server "irc.gnu.org")
+                   (erc-server-announced-name "my.gnu.org")
+                   (erc-session-port 6697)
+                   (erc-network 'GNU.chat)
+                   (erc-server-current-nick "tester")
+                   (erc-networks--id (erc-networks--id-create nil)))
+              (should (string= (erc--auth-source-search :user "#chan")
+                               "baz"))))
+
+          (ert-info ("Peer next")
+            (let* ((erc-server-announced-name "irc.gnu.org")
+                   (erc-session-port 6697)
+                   (erc-network 'GNU.chat)
+                   (erc-server-current-nick "tester")
+                   (erc-networks--id (erc-networks--id-create nil)))
+              (should (string= (erc--auth-source-search :user "#chan")
+                               "bar"))))
+
+          (ert-info ("Network used as fallback")
+            (let* ((erc-session-port 6697)
+                   (erc-network 'GNU.chat)
+                   (erc-server-current-nick "tester")
+                   (erc-networks--id (erc-networks--id-create nil)))
+              (should (string= (erc--auth-source-search :user "#chan")
+                               "foo")))))))))
+
+(ert-deftest erc-services-tests--auth-source-pass--overrides ()
+  (let* ((store
+          `(,@erc-join-tests--auth-source-pass-entries
+            ("GNU.chat:6697/#chan"
+             ("port" . "6697") ("user" . "#chan") (secret . "spam"))
+            ("my.gnu.org:irc/#fsf"
+             ("port" . "irc") ("user" . "#fsf") (secret . "42"))
+            ("irc.gnu.org:6667"
+             ("port" . "6667") (secret . "sesame"))
+            ("MyHost:irc"
+             ("port" . "irc") (secret . "456"))
+            ("MyHost:6667"
+             ("port" . "6667") (secret . "123"))))
+         (auth-sources '(password-store))
+         (auth-source-do-cache nil)
+         (erc-session-server "irc.gnu.org")
+         (erc-server-announced-name "my.gnu.org")
+         (erc-network 'GNU.chat)
+         (erc-server-current-nick "tester")
+         (erc-networks--id (erc-networks--id-create nil))
+         (erc-session-port 6667))
+
+    (cl-letf (((symbol-function 'auth-source-pass-parse-entry)
+               (apply-partially #'erc-services-tests--asp-parse-entry store))
+              ((symbol-function 'auth-source-pass-entries)
+               (lambda () (mapcar #'car store))))
+
+      (ert-info ("More specific port")
+        (let ((erc-session-port 6697))
+          (should (string= (erc--auth-source-search :user "#chan") "spam"))))
+
+      (ert-info ("Network wins")
+        (should (string= (erc--auth-source-search :user '("#fsf")) "42")))
+
+      (ert-info ("Actual override")
+        (should (string= (erc--auth-source-search :port "6667") "sesame")))
+
+      (ert-info ("Overrides don't interfere with post-processing")
+        (should (string= (erc--auth-source-search :host "MyHost")
+                         "123"))))))
+
+;;;; The services module
+
+(ert-deftest erc-nickserv-get-password ()
+  (should erc-prompt-for-nickserv-password)
+  (ert-with-temp-file netrc-file
+    :prefix "erc-nickserv-get-password"
+    :text (mapconcat 'identity
+                     '("machine GNU/chat port 6697 user bob password spam"
+                       "machine FSF.chat port 6697 user bob password sesame"
+                       "machine MyHost port irc password 123")
+                     "\n")
+
+    (let* ((auth-sources (list netrc-file))
+           (auth-source-do-cache nil)
+           (erc-nickserv-passwords '((FSF.chat (("alice" . "foo")
+                                                ("joe" . "bar")))))
+           (erc-use-auth-source-for-nickserv-password t)
+           (erc-session-server "irc.gnu.org")
+           (erc-server-announced-name "my.gnu.org")
+           (erc-network 'FSF.chat)
+           (erc-server-current-nick "tester")
+           (erc-networks--id (erc-networks--id-create nil))
+           (erc-session-port 6697))
+
+      (ert-info ("Lookup custom option")
+        (should (string= (erc-nickserv-get-password "alice") "foo")))
+
+      (ert-info ("Auth source")
+        (ert-info ("Network")
+          (should (string= (erc-nickserv-get-password "bob") "sesame")))
+
+        (ert-info ("Network ID")
+          (let ((erc-networks--id (erc-networks--id-create 'GNU/chat)))
+            (should (string= (erc-nickserv-get-password "bob") "spam")))))
+
+      (ert-info ("Read input")
+        (should (string=
+                 (ert-simulate-keys "baz\r" (erc-nickserv-get-password "mike"))
+                 "baz")))
+
+      (ert-info ("Failed")
+        (should-not (ert-simulate-keys "\r"
+                      (erc-nickserv-get-password "fake")))))))
+
+
+;;; erc-services-tests.el ends here