Re: A few questions about c++-ts-mode.

[Filippo Argiolas]

On Thu, May 9, 2024 at 7:53 AM Eli Zaretskii <eliz@gnu.org> wrote:
>
> > From: Filippo Argiolas <filippo.argiolas@gmail.com>
> > Date: Thu, 9 May 2024 07:34:58 +0200
> > Cc: Ergus <spacibba@aol.com>, emacs-devel@gnu.org, casouri@gmail.com
> >
> > > If the only solution is language injection, then doing that our usual
> > > way (with regexps etc.) is easier and more flexible.  I thought I saw
> > > some commits in the C++ grammar that actually support that in the
> > > grammar itself.  If there is such support, we should use it, IMO.
> > >
> >
> > Sorry to intrude, may I ask what's the problem with language
> > injection? it seems the perfect use case for this.
>
> I didn't say there was a problem, I said that doing it with regexp
> etc. would be easier and more flexible.
>
> Language injection AFAIU requires an additional grammar library, which
> means someone must compile it, the end-user must ensure it's
> installed, etc.  IOW, it makes the disadvantages of tree-sitter more
> prominent, for the benefit of a very minor feature.  From where I
> stand, that makes the balance tip in favor of the simpler solution,
> which users could more easily activate and customize.

I know you disagree with this path, and I tend to agree, but a little
experimenting I guess won't hurt.
I did some experiment to see how really easy and flexible this would
be with current code and language injections.
It's pretty basic but I must say I'm pretty pleased about how easy
this was. Tree-sitter is really powerful and nice to work with.
Still not happy about the faces I'm using but it's a start.
Grammars are from [1] for doxygen and [2] for printf format strings.

(defvar fa/ts-font-lock-settings
  (treesit-font-lock-rules
   :language 'printf
   :feature 'format
   :override 'prepend
   '((format) @font-lock-constant-face)
   :language 'doxygen
   :feature 'doxy
   :override 'prepend
   '((tag_name) @font-lock-doc-markup-face
     (brief_header) @font-lock-doc-face
     (storageclass) @font-lock-keyword-face
     (type) @font-lock-type-face
     (identifier) @font-lock-variable-name-face
     (function_link) @font-lock-function-name-face
     (link) @link
     (emphasis) @bold
     (code_block (code_block_content) @default)
     (code_word (code) @default)
     ((tag_name) @bold (:match ".note" @bold))
     ((tag_name) @warning (:match ".warning" @warning))
     ((tag_name) @error (:match ".error" @error)))
))

(add-hook 'c-ts-mode-hook
          (lambda () (setq-local treesit-font-lock-settings
                 (append treesit-font-lock-settings
                     fa/ts-font-lock-settings))))
(defvar fa/ts-range-settings
  (treesit-range-rules
   :embed 'printf
   :local t
   :host 'c
   '((call_expression (argument_list (string_literal (string_content)
@capture))))
   :embed 'doxygen
   :local t
   :host 'c
   '(((comment) @capture (:match "/\\*[\\*!]" @capture)))))

(add-hook 'c-ts-mode-hook
          (lambda ()
            (setq-local treesit-range-settings (append treesit-range-settings
                                                       fa/ts-range-settings))))

1. https://github.com/tree-sitter-grammars/tree-sitter-doxygen
2. https://github.com/pstuifzand/tree-sitter-printf