[bug-inetutils] ANNOUNCE: Daily snapshot and autobuild service

[Simon Josefsson]

Hi!  I added inetutils to my daily build scripts, and from now on
there should be a daily snapshot available from:

http://daily.josefsson.org/inetutils/

That is, assuming CVS builds every day... ;-)

If the patch below is installed, there will also be logs from the
builds available at:

http://autobuild.josefsson.org/

Anyone can e-mail build logs to address@hidden and they will
show up on the same web page.  This is a good way to test of it builds
on many platforms.

I notice that 'inetutils' doesn't contain _any_ self tests, which
seems bad.  Maybe we could start working on that...

Any objections to installing the patch?

/Simon

Index: configure.ac
===================================================================
RCS file: /sources/inetutils/inetutils/configure.ac,v
retrieving revision 1.36
diff -u -p -r1.36 configure.ac
--- configure.ac        16 Mar 2007 19:09:51 -0000      1.36
+++ configure.ac        11 Apr 2007 12:44:55 -0000
@@ -28,6 +28,8 @@ AC_CONFIG_AUX_DIR([build-aux])
 AM_CONFIG_HEADER([config.h:config.hin])
 AC_CANONICAL_SYSTEM # FIXME: Why not just _HOST?
 
+AB_INIT
+
 # config.h turns this on, so make sure it's on for our tests too
 #CPPFLAGS=-D_BSD_SOURCE
 
Index: m4/autobuild.m4
===================================================================
RCS file: m4/autobuild.m4
diff -N m4/autobuild.m4
--- /dev/null   1 Jan 1970 00:00:00 -0000
+++ m4/autobuild.m4     11 Apr 2007 12:44:55 -0000
@@ -0,0 +1,44 @@
+# autobuild.m4 serial 3
+# Copyright (C) 2004, 2006 Simon Josefsson
+#
+# This file is free software, distributed under the terms of the GNU
+# General Public License.  As a special exception to the GNU General
+# Public License, this file may be distributed as part of a program
+# that contains a configuration script generated by Autoconf, under
+# the same distribution terms as the rest of that program.
+#
+# This file can can be used in projects which are not available under
+# the GNU General Public License or the GNU Library General Public
+# License but which still want to provide support for Autobuild.
+
+# Usage: AB_INIT([MODE]).
+AC_DEFUN([AB_INIT],
+[
+       AC_REQUIRE([AC_CANONICAL_BUILD])
+       AC_REQUIRE([AC_CANONICAL_HOST])
+
+       if test -z "$AB_PACKAGE"; then
+          AB_PACKAGE=${PACKAGE_NAME:-$PACKAGE}
+       fi
+       AC_MSG_NOTICE([autobuild project... $AB_PACKAGE])
+
+       if test -z "$AB_VERSION"; then
+          AB_VERSION=${PACKAGE_VERSION:-$VERSION}
+       fi
+       AC_MSG_NOTICE([autobuild revision... $AB_VERSION])
+
+       hostname=`hostname`
+       if test "$hostname"; then
+          AC_MSG_NOTICE([autobuild hostname... $hostname])
+       fi
+
+       ifelse([$1],[],,[AC_MSG_NOTICE([autobuild mode... $1])])
+
+       date=`date +%Y%m%d-%H%M%S`
+       if test "$?" != 0; then
+          date=`date`
+       fi
+       if test "$date"; then
+          AC_MSG_NOTICE([autobuild timestamp... $date])
+       fi
+])