# Maintainer: Alexey Pavlov <address@hidden>

_realname=guile

pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=2.9.2
pkgrel=1
pkgdesc="a portable, embeddable Scheme implementation written in C (mingw-w64)"
arch=('any')
url="https://www.gnu.org/software/guile/"
license=("GPL")
makedepends=("${MINGW_PACKAGE_PREFIX}-gcc"
    "${MINGW_PACKAGE_PREFIX}-pkg-config"
    "${MINGW_PACKAGE_PREFIX}-libtool"
    "texinfo"
    "${MINGW_PACKAGE_PREFIX}-crt"
)
depends=(
    "${MINGW_PACKAGE_PREFIX}-pdcurses"
    "${MINGW_PACKAGE_PREFIX}-gmp"
    "${MINGW_PACKAGE_PREFIX}-libunistring"
    "${MINGW_PACKAGE_PREFIX}-gc"
    "${MINGW_PACKAGE_PREFIX}-readline"
    "${MINGW_PACKAGE_PREFIX}-libffi"
    )
options=('strip' 'staticlibs')
#source=("https://ftp.gnu.org/pub/gnu/${_realname}/${_realname}-${pkgver}.tar.gz"
source=("guile-2.9.2.tar.gz"
        0001-Get-latest-poll-module-from-gnulib-to-fix-compilatio.patch
        0002-Fix-error-missing-netinet-tcp_h-on-mingw-w64.patch
        0003-Fix-compilation-error-libguile-posix-w32_h.patch
        0004-Fix-posix.c-for-mingw-w64.patch
)
sha256sums=('823dce6c89a993663dbd3eba058cb65daa7a67ef120fcf0295f6ba5682c05fef'
	    'SKIP'
	    'SKIP'
	    'SKIP'
	    'SKIP'           
            )

prepare() {
  cd "${srcdir}"/${_realname}-${pkgver}
  patch -p1 -i ${srcdir}/0001-Get-latest-poll-module-from-gnulib-to-fix-compilatio.patch
  patch -p1 -i ${srcdir}/0002-Fix-error-missing-netinet-tcp_h-on-mingw-w64.patch
  patch -p1 -i ${srcdir}/0003-Fix-compilation-error-libguile-posix-w32_h.patch
  patch -p1 -i ${srcdir}/0004-Fix-posix.c-for-mingw-w64.patch
  
  autoreconf -fi
}

build() {
  mkdir -p "${srcdir}/build-${MINGW_CHOST}"
  export lt_cv_deplibs_check_method='pass_all'
  cd "${srcdir}/build-${MINGW_CHOST}"
  "${srcdir}"/${_realname}-${pkgver}/configure \
    --prefix=${MINGW_PREFIX} \
    --build=${MINGW_CHOST} \
    --host=${MINGW_CHOST} \
    --enable-shared \
    --enable-static \
    --enable-error-on-warning=no \
    --enable-jit=no
#    --without-threads \ causes sigprocmask failure in null-threads.h
    make
#   make V=1
}



package() {
  cd "${srcdir}/build-${MINGW_CHOST}"
  make DESTDIR="$pkgdir" install
  find "${pkgdir}${MINGW_PREFIX}" -name '*.def' -o -name '*.exp' | xargs -rtl1 rm

  rm -r "${pkgdir}${MINGW_PREFIX}"/share/info
  rm -r "${pkgdir}${MINGW_PREFIX}"/share/man
}