Re: Bison 3.0.3 (stable)

[Akim Demaille]

> Le 20 janv. 2015 à 16:29, Thomas Jahns <address@hidden> a écrit :
> 
> On 01/19/15 18:59, Akim Demaille wrote:
>> This time, the syncline tests should not be skipped.
> 
> Initially they got all skipped now.
> 
>> @@ -92,6 +97,8 @@ AT_CHECK([[$PERL -p -0777 - stderr <<\EOF
>> 
>>    # 2. Normalize the lines we kept.
>> 
>> +  # xlc messages.
>> +  s/^"(.*?)", line ([\w.]*): /$1:$2: /gm;
>>    # Remove column.
>>    s/^([^:]+:\d+)[.:][^:]+:(.+)$/$][1:$][2/gm;
>>    # Map all combinations of "error: " and "#error: " to "#error ".
> 
> After I adjusted the new substitution by replacing
> 
> $1:$2
> 
> with
> 
> $][1:$][2

You are very right.  Unprotected, $1 and $2 are handled by m4, who
thinks that $1 and $2 denote the arguments of the macros.

> because I thought I had spotted the oversight, that still happens:
> 187: Prologue syncline                               skipped 
> (synclines.at:172)
> 188: %union syncline                                 skipped 
> (synclines.at:190)
> 189: %union name syncline                            skipped 
> (synclines.at:230)
> 190: Postprologue syncline                           skipped 
> (synclines.at:240)
> 191: Action syncline                                 skipped 
> (synclines.at:264)
> 192: Epilogue syncline                               skipped 
> (synclines.at:283)
> 193: %code top syncline                              skipped 
> (synclines.at:300)

That's because the error message still does not have the proper form.
Maybe the appended patch, in the "next" branch currently, does it?

> If I got it right, this is an M4 script generating a shell script that 
> produces a Perl-script. So there might still be some dragons here. :-)

No, you were right.  But it's the "1506-205 (S)" parts that were
not handled correctly.  If that skips again, could you please
try one of these tests and get its log?  Something like

  make check TESTSUITEFLAGS='187 -d -v -x'

and send

  tests/testsuite.dir/187/testsuite.log

Thanks!


commit 0b0370ff42af17689da7edf28294a5262e450610
Author: Akim Demaille <address@hidden>
Date:   Mon Jan 19 18:51:54 2015 +0100

    tests: be more robust to unrecognized synclines, and try to recognize xlc
    
    Reported by Thomas Jahns.
    http://lists.gnu.org/archive/html/bug-bison/2015-01/msg00059.html
    
    * tests/synclines.at (AT_SYNCLINES_COMPILE): Rename as...
    (_AT_SYNCLINES_COMPILE): this.
    Try to recognize xlc locations.
    (AT_SYNCLINES_COMPILE): New.  Skips the test if we can't read the
    synclines.

diff --git a/tests/synclines.at b/tests/synclines.at
index 260e2f9..00c2fc1 100644
--- a/tests/synclines.at
+++ b/tests/synclines.at
@@ -19,13 +19,13 @@
 AT_BANNER([[User Actions.]])
 
 
-# AT_SYNCLINES_COMPILE(FILE)
-# --------------------------
+# _AT_SYNCLINES_COMPILE(FILE)
+# ---------------------------
 # Compile FILE expecting an error, and save in the file stdout the
 # normalized output.  Ignore the exit status, since some compilers
 # (e.g. c89 on IRIX 6.5) trigger warnings on '#error', instead of
 # errors.
-m4_define([AT_SYNCLINES_COMPILE],
+m4_define([_AT_SYNCLINES_COMPILE],
 [AT_CHECK([$CC $CFLAGS $CPPFLAGS -c $1], [ignore], [], [stderr])
 
 # Transform stderr into something like this:
@@ -75,6 +75,12 @@ m4_define([AT_SYNCLINES_COMPILE],
 # When c++ is used to compiler C, we might have more messages (Clang 3.2):
 #
 #    clang: warning: treating 'c' input as 'c++' when in C++ mode, this 
behavior is deprecated
+#
+#
+# xlc reports things like:
+#
+#    "input.yy", line 80.21: 1540-0218 (S) The call does not match any 
parameter list for "operator<<".
+#    "/usr/vacpp/include/iosfwd", line 32.6: 1506-205 (S) #error This file to 
be used only with IBM VisualAge C++ v4 and later compilers
 
 AT_CHECK([[$PERL -p -0777 - stderr <<\EOF
   # 1. Remove useless lines.
@@ -92,6 +98,8 @@ AT_CHECK([[$PERL -p -0777 - stderr <<\EOF
 
   # 2. Normalize the lines we kept.
 
+  # xlc messages.  Remove also error identifier (e.g., "1540-0218 (S)").
+  s/^"(.*?)", line ([\w.]*): \d+-\d+ \(.\) /$][1:$][2: /gm;
   # Remove column.
   s/^([^:]+:\d+)[.:][^:]+:(.+)$/$][1:$][2/gm;
   # Map all combinations of "error: " and "#error: " to "#error ".
@@ -101,13 +109,14 @@ EOF
   0, [stdout])
 ])
 
-# AT_TEST(TITLE, INPUT, ERROR-MSG)
-# --------------------------------
-# Check that compiling the parser produced from INPUT cause GCC
-# to issue ERROR-MSG.
-m4_pushdef([AT_TEST],
-[AT_SETUP([$1])
-AT_BISON_OPTION_PUSHDEFS
+
+
+# AT_SYNCLINES_COMPILE(FILE)
+# --------------------------
+# Compile FILE expecting an error, and save in the file stdout the
+# normalized output.  If we can't get a trustable location
+# from the compiler, just skip the test.
+#
 # It seems impossible to find a generic scheme to check the location
 # of an error.  Even requiring GCC is not sufficient, since for instance
 # the version modified by Apple:
@@ -124,15 +133,29 @@ AT_BISON_OPTION_PUSHDEFS
 #
 # | input.y:2: "2"
 # | cpp-precomp: warning: errors during smart preprocessing, retrying in basic 
mode
-
+m4_define([AT_SYNCLINES_COMPILE],
+[# Check if we can trust location translation.
 AT_DATA([syncline.c],
 [[#error "1"
 int i; /* avoids -pedantic warning about an empty translation unit. */
 ]])
 
-AT_SYNCLINES_COMPILE([syncline.c])
+_AT_SYNCLINES_COMPILE([syncline.c])
 AT_CHECK([[test "`cat stdout`" = 'syncline.c:1: @%:@error "1"' || exit 77]])
 
+# Then work for real.
+_AT_SYNCLINES_COMPILE([$1])
+])
+
+
+# AT_TEST(TITLE, INPUT, ERROR-MSG)
+# --------------------------------
+# Check that compiling the parser produced from INPUT cause GCC
+# to issue ERROR-MSG.
+m4_pushdef([AT_TEST],
+[AT_SETUP([$1])
+AT_BISON_OPTION_PUSHDEFS
+
 AT_DATA([[input.y]], [$2])
 AT_BISON_CHECK([-o input.c input.y])
 AT_SYNCLINES_COMPILE([input.c])


> If I got it right, this is an M4 script generating a shell script that 
> produces a Perl-script. So there might still be some dragons here. :-)
> 
> Regards, Thomas
> -- 
> Thomas Jahns
> HD(CP)^2
> Abteilung Anwendungssoftware
> 
> Deutsches Klimarechenzentrum GmbH
> Bundesstraße 45a • D-20146 Hamburg • Germany
> 
> Phone:  +49 40 460094-151
> Fax:    +49 40 460094-270
> Email:  Thomas Jahns <address@hidden>
> URL:    www.dkrz.de
> 
> Geschäftsführer: Prof. Dr. Thomas Ludwig
> Sitz der Gesellschaft: Hamburg
> Amtsgericht Hamburg HRB 39784
>