[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
43-autoconf-programs.patch
|
From: |
Akim Demaille |
|
Subject: |
43-autoconf-programs.patch |
|
Date: |
Wed, 22 Aug 2001 08:28:17 +0200 |
Index: ChangeLog
from Akim Demaille <address@hidden>
* lib/autoconf/general.m4 (AC_SHELL_PATH_WALK, AC_CHECK_PROG)
(AC_CHECK_PROGS, AC_PATH_PROG, AC_PATH_PROGS, AC_CHECK_TOOL_PREFIX)
(AC_PATH_TOOL, AC_CHECK_TOOL, AC_CHECK_TOOLS): Move to...
* lib/autoconf/programs.m4: here.
* lib/autoconf/specific.m4 (_AC_PROG_ECHO, AC_PROG_MAKE_SET)
(AC_PROG_RANLIB, AC_PROG_YACC, AC_PROG_LEX, _AC_DECL_YYTEXT)
(AC_PROG_INSTALL, AC_PROG_LN_S, AC_RSH): Move to...
* lib/autoconf/programs.m4: here.
(_AC_DECL_YYTEXT): Rename as...
(_AC_PROG_LEX_YYTEXT_DECL): this.
* lib/autoconf/autoconf.m4, lib/autoconf/Makefile.am
* tests/Makefile.am, tests/suite.am: Adjust.
Index: lib/autoconf/Makefile.am
--- lib/autoconf/Makefile.am Tue, 21 Aug 2001 10:28:25 +0200 akim
+++ lib/autoconf/Makefile.am Tue, 21 Aug 2001 10:36:39 +0200 akim
@@ -21,7 +21,7 @@
distautoconflib_DATA = autoconf.m4 \
general.m4 oldnames.m4 specific.m4 \
lang.m4 c.m4 fortran.m4 \
- functions.m4 headers.m4 types.m4 libs.m4
+ functions.m4 headers.m4 types.m4 libs.m4 programs.m4
nodistautoconflibdir = $(pkgdatadir)/autoconf
# The order matters: we need version.m4 to build autoconf.m4f.
nodistautoconflib_DATA = version.m4 autoconf.m4f
@@ -132,7 +132,8 @@ autoconf.m4f: $(srclibdir)/m4sugar/m4sug
$(srclibdir)/autoconf/functions.m4 \
$(srclibdir)/autoconf/headers.m4 \
$(srclibdir)/autoconf/types.m4 \
- $(srclibdir)/autoconf/libs.m4
+ $(srclibdir)/autoconf/libs.m4 \
+ $(srclibdir)/autoconf/programs.m4
# Files that should be removed, but which Automake does not know.
CLEANFILES = autoconf.m4f
Index: lib/autoconf/autoconf.m4
--- lib/autoconf/autoconf.m4 Tue, 21 Aug 2001 10:28:25 +0200 akim
+++ lib/autoconf/autoconf.m4 Tue, 21 Aug 2001 10:42:56 +0200 akim
@@ -53,6 +53,7 @@
m4_include([autoconf/version.m4])
m4_include([autoconf/general.m4])
+m4_include([autoconf/programs.m4])
m4_include([autoconf/lang.m4])
m4_include([autoconf/c.m4])
m4_include([autoconf/fortran.m4])
Index: lib/autoconf/general.m4
--- lib/autoconf/general.m4 Tue, 21 Aug 2001 10:28:25 +0200 akim
+++ lib/autoconf/general.m4 Tue, 21 Aug 2001 10:38:19 +0200 akim
@@ -628,6 +628,30 @@ AC_DEFUN([AC_PREFIX_DEFAULT],
[m4_divert_text([DEFAULTS], [ac_default_prefix=$1])])
+# AC_PREFIX_PROGRAM(PROGRAM)
+# --------------------------
+# Guess the value for the `prefix' variable by looking for
+# the argument program along PATH and taking its parent.
+# Example: if the argument is `gcc' and we find /usr/local/gnu/bin/gcc,
+# set `prefix' to /usr/local/gnu.
+# This comes too late to find a site file based on the prefix,
+# and it might use a cached value for the path.
+# No big loss, I think, since most configures don't use this macro anyway.
+AC_DEFUN([AC_PREFIX_PROGRAM],
+[dnl Get an upper case version of $[1].
+m4_pushdef([AC_Prog], m4_toupper([$1]))dnl
+if test "x$prefix" = xNONE; then
+dnl We reimplement AC_MSG_CHECKING (mostly) to avoid the ... in the middle.
+ echo $ECHO_N "checking for prefix by $ECHO_C" >&AS_MESSAGE_FD
+ AC_PATH_PROG(m4_quote(AC_Prog), [$1])
+ if test -n "$ac_cv_path_[]AC_Prog"; then
+ prefix=`AS_DIRNAME(["$ac_cv_path_[]AC_Prog"])`
+ fi
+fi
+m4_popdef([AC_Prog])dnl
+])# AC_PREFIX_PROGRAM
+
+
# AC_CONFIG_SRCDIR([UNIQUE-FILE-IN-SOURCE-DIR])
# ---------------------------------------------
# UNIQUE-FILE-IN-SOURCE-DIR is a filename unique to this package,
@@ -2267,244 +2291,6 @@ AC_DEFUN([AC_INCLUDES_DEFAULT],
],
[AC_REQUIRE([_AC_INCLUDES_DEFAULT_REQUIREMENTS])dnl
$ac_includes_default])])
-
-
-
-
-## ----------------------- ##
-## Checking for programs. ##
-## ----------------------- ##
-
-
-# AC_SHELL_PATH_WALK([PATH = $PATH], BODY)
-# ----------------------------------------
-# Walk through PATH running BODY for each `ac_dir'.
-#
-# `$ac_dummy' forces splitting on constant user-supplied paths.
-# POSIX.2 word splitting is done only on the output of word
-# expansions, not every word. This closes a longstanding sh security
-# hole.
-m4_define([AC_SHELL_PATH_WALK],
-[ac_save_IFS=$IFS; IFS=$ac_path_separator
-ac_dummy="m4_default([$1], [$PATH])"
-for ac_dir in $ac_dummy; do
- IFS=$ac_save_IFS
- test -z "$ac_dir" && ac_dir=.
- $2
-done
-])
-
-
-# AC_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
-# [VALUE-IF-FOUND], [VALUE-IF-NOT-FOUND],
-# [PATH], [REJECT])
-# -----------------------------------------------------
-AC_DEFUN([AC_CHECK_PROG],
-[# Extract the first word of "$2", so it can be a program name with args.
-set dummy $2; ac_word=$[2]
-AC_MSG_CHECKING([for $ac_word])
-AC_CACHE_VAL(ac_cv_prog_$1,
-[if test -n "$$1"; then
- ac_cv_prog_$1="$$1" # Let the user override the test.
-else
-m4_ifvaln([$6],
-[ ac_prog_rejected=no])dnl
- AC_SHELL_PATH_WALK([$5],
-[AS_EXECUTABLE_P("$ac_dir/$ac_word") || continue
-m4_ifvaln([$6],
-[if test "$ac_dir/$ac_word" = "$6"; then
- ac_prog_rejected=yes
- continue
-fi])dnl
-ac_cv_prog_$1="$3"
-echo "$as_me:__oline__: found $ac_dir/$ac_word" >&AS_MESSAGE_LOG_FD
-break])
-m4_ifvaln([$6],
-[if test $ac_prog_rejected = yes; then
- # We found a bogon in the path, so make sure we never use it.
- set dummy $ac_cv_prog_$1
- shift
- if test address@hidden:@] != 0; then
- # We chose a different compiler from the bogus one.
- # However, it has the same basename, so the bogon will be chosen
- # first if we set $1 to just the basename; use the full file name.
- shift
- set dummy "$ac_dir/$ac_word" ${1+"address@hidden"}
- shift
- ac_cv_prog_$1="address@hidden"
-m4_if([$2], [$4],
-[ else
- # Default is a loser.
- AC_MSG_ERROR([$1=$6 unacceptable, but no other $4 found in dnl
-m4_default([$5], [\$PATH])])
-])dnl
- fi
-fi])dnl
-dnl If no 4th arg is given, leave the cache variable unset,
-dnl so AC_CHECK_PROGS will keep looking.
-m4_ifvaln([$4],
-[ test -z "$ac_cv_prog_$1" && ac_cv_prog_$1="$4"])dnl
-fi])dnl
-$1=$ac_cv_prog_$1
-if test -n "$$1"; then
- AC_MSG_RESULT([$$1])
-else
- AC_MSG_RESULT([no])
-fi
-AC_SUBST($1)dnl
-])# AC_CHECK_PROG
-
-
-# AC_CHECK_PROGS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
-# [PATH])
-# ------------------------------------------------------------------
-AC_DEFUN([AC_CHECK_PROGS],
-[for ac_prog in $2
-do
- AC_CHECK_PROG([$1], [$ac_prog], [$ac_prog], , [$4])
- test -n "$$1" && break
-done
-m4_ifvaln([$3], [test -n "$$1" || $1="$3"])])
-
-
-# AC_PATH_PROG(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
-# -----------------------------------------------------------------------
-AC_DEFUN([AC_PATH_PROG],
-[# Extract the first word of "$2", so it can be a program name with args.
-set dummy $2; ac_word=$[2]
-AC_MSG_CHECKING([for $ac_word])
-AC_CACHE_VAL([ac_cv_path_$1],
-[case $$1 in
- [[\\/]]* | ?:[[\\/]]*)
- ac_cv_path_$1="$$1" # Let the user override the test with a path.
- ;;
- *)
- AC_SHELL_PATH_WALK([$4],
-[if AS_EXECUTABLE_P("$ac_dir/$ac_word"); then
- ac_cv_path_$1="$ac_dir/$ac_word"
- echo "$as_me:__oline__: found $ac_dir/$ac_word" >&AS_MESSAGE_LOG_FD
- break
-fi])
-dnl If no 3rd arg is given, leave the cache variable unset,
-dnl so AC_PATH_PROGS will keep looking.
-m4_ifvaln([$3],
-[ test -z "$ac_cv_path_$1" && ac_cv_path_$1="$3"])dnl
- ;;
-esac])dnl
-AC_SUBST([$1], [$ac_cv_path_$1])
-if test -n "$$1"; then
- AC_MSG_RESULT([$$1])
-else
- AC_MSG_RESULT([no])
-fi
-])# AC_PATH_PROG
-
-
-# AC_PATH_PROGS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
-# [PATH])
-# -----------------------------------------------------------------
-AC_DEFUN([AC_PATH_PROGS],
-[for ac_prog in $2
-do
- AC_PATH_PROG([$1], [$ac_prog], , [$4])
- test -n "$$1" && break
-done
-m4_ifvaln([$3], [test -n "$$1" || $1="$3"])dnl
-])
-
-
-
-
-## -------------------- ##
-## Checking for tools. ##
-## -------------------- ##
-
-
-# AC_CHECK_TOOL_PREFIX
-# --------------------
-AU_DEFUN([AC_CHECK_TOOL_PREFIX])
-
-
-# AC_PATH_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
-# -----------------------------------------------------------------------
-# (Use different variables $1 and ac_pt_$1 so that cache vars don't conflict.)
-AC_DEFUN([AC_PATH_TOOL],
-[if test -n "$ac_tool_prefix"; then
- AC_PATH_PROG([$1], [${ac_tool_prefix}$2], , [$4])
-fi
-if test -z "$ac_cv_path_$1"; then
- ac_pt_$1=$$1
- AC_PATH_PROG([ac_pt_$1], [$2], [$3], [$4])
- $1=$ac_pt_$1
-else
- $1="$ac_cv_path_$1"
-fi
-])# AC_PATH_TOOL
-
-
-# AC_CHECK_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
-# ------------------------------------------------------------------------
-# (Use different variables $1 and ac_ct_$1 so that cache vars don't conflict.)
-AC_DEFUN([AC_CHECK_TOOL],
-[if test -n "$ac_tool_prefix"; then
- AC_CHECK_PROG([$1], [${ac_tool_prefix}$2], [${ac_tool_prefix}$2], , [$4])
-fi
-if test -z "$ac_cv_prog_$1"; then
- ac_ct_$1=$$1
- AC_CHECK_PROG([ac_ct_$1], [$2], [$2], [$3], [$4])
- $1=$ac_ct_$1
-else
- $1="$ac_cv_prog_$1"
-fi
-])# AC_CHECK_TOOL
-
-
-# AC_CHECK_TOOLS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
-# [PATH])
-# ------------------------------------------------------------------
-# Check for each tool in PROGS-TO-CHECK-FOR with the cross prefix. If
-# none can be found with a cross prefix, then use the first one that
-# was found without the cross prefix.
-AC_DEFUN([AC_CHECK_TOOLS],
-[if test -n "$ac_tool_prefix"; then
- for ac_prog in $2
- do
- AC_CHECK_PROG([$1],
- [$ac_tool_prefix$ac_prog], [$ac_tool_prefix$ac_prog],,
- [$4])
- test -n "$$1" && break
- done
-fi
-if test -z "$$1"; then
- ac_ct_$1=$$1
- AC_CHECK_PROGS([ac_ct_$1], [$2], [$3], [$4])
- $1=$ac_ct_$1
-fi
-])# AC_CHECK_TOOLS
-
-
-# AC_PREFIX_PROGRAM(PROGRAM)
-# --------------------------
-# Guess the value for the `prefix' variable by looking for
-# the argument program along PATH and taking its parent.
-# Example: if the argument is `gcc' and we find /usr/local/gnu/bin/gcc,
-# set `prefix' to /usr/local/gnu.
-# This comes too late to find a site file based on the prefix,
-# and it might use a cached value for the path.
-# No big loss, I think, since most configures don't use this macro anyway.
-AC_DEFUN([AC_PREFIX_PROGRAM],
-[dnl Get an upper case version of $[1].
-m4_pushdef([AC_Prog], m4_toupper([$1]))dnl
-if test "x$prefix" = xNONE; then
-dnl We reimplement AC_MSG_CHECKING (mostly) to avoid the ... in the middle.
- echo $ECHO_N "checking for prefix by $ECHO_C" >&AS_MESSAGE_FD
- AC_PATH_PROG(m4_quote(AC_Prog), [$1])
- if test -n "$ac_cv_path_[]AC_Prog"; then
- prefix=`AS_DIRNAME(["$ac_cv_path_[]AC_Prog"])`
- fi
-fi
-m4_popdef([AC_Prog])dnl
-])# AC_PREFIX_PROGRAM
Index: lib/autoconf/specific.m4
--- lib/autoconf/specific.m4 Tue, 21 Aug 2001 10:28:25 +0200 akim
+++ lib/autoconf/specific.m4 Tue, 21 Aug 2001 10:38:57 +0200 akim
@@ -1,5 +1,5 @@
# This file is part of Autoconf. -*- Autoconf -*-
-# Macros that test for specific features.
+# Macros that test for specific, unclassified, features.
# Copyright 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001
# Free Software Foundation, Inc.
#
@@ -48,242 +48,6 @@
# Written by David MacKenzie, with help from
# Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
# Roland McGrath, Noah Friedman, david d zuhn, and many others.
-
-
-## --------------------- ##
-## Checks for programs. ##
-## --------------------- ##
-
-
-# _AC_PROG_ECHO
-# -------------
-# Check whether to use -n, \c, or newline-tab to separate
-# checking messages from result messages.
-# Don't try to cache, since the results of this macro are needed to
-# display the checking message. In addition, caching something used once
-# has little interest.
-# Idea borrowed from dist 3.0. Use `*c*,', not `*c,' because if `\c'
-# failed there is also a new-line to match.
-m4_define([_AC_PROG_ECHO],
-[case `echo "testing\c"; echo 1,2,3`,`echo -n testing; echo 1,2,3` in
- *c*,-n*) ECHO_N= ECHO_C='
-' ECHO_T=' ' ;;
- *c*,* ) ECHO_N=-n ECHO_C= ECHO_T= ;;
- *) ECHO_N= ECHO_C='\c' ECHO_T= ;;
-esac
-AC_SUBST(ECHO_C)dnl
-AC_SUBST(ECHO_N)dnl
-AC_SUBST(ECHO_T)dnl
-])# _AC_PROG_ECHO
-
-
-# AC_PROG_MAKE_SET
-# ----------------
-# Define SET_MAKE to set ${MAKE} if make doesn't.
-AC_DEFUN([AC_PROG_MAKE_SET],
-[AC_MSG_CHECKING([whether ${MAKE-make} sets \${MAKE}])
-set dummy ${MAKE-make}; ac_make=`echo "$[2]" | sed 'y,./+-,__p_,'`
-AC_CACHE_VAL(ac_cv_prog_make_${ac_make}_set,
-[cat >conftest.make <<\_ACEOF
-all:
- @echo 'ac_maketemp="${MAKE}"'
-_ACEOF
-# GNU make sometimes prints "make[1]: Entering...", which would confuse us.
-eval `${MAKE-make} -f conftest.make 2>/dev/null | grep temp=`
-if test -n "$ac_maketemp"; then
- eval ac_cv_prog_make_${ac_make}_set=yes
-else
- eval ac_cv_prog_make_${ac_make}_set=no
-fi
-rm -f conftest.make])dnl
-if eval "test \"`echo '$ac_cv_prog_make_'${ac_make}_set`\" = yes"; then
- AC_MSG_RESULT([yes])
- SET_MAKE=
-else
- AC_MSG_RESULT([no])
- SET_MAKE="MAKE=${MAKE-make}"
-fi
-AC_SUBST([SET_MAKE])dnl
-])# AC_PROG_MAKE_SET
-
-
-# AC_PROG_RANLIB
-# --------------
-AC_DEFUN([AC_PROG_RANLIB],
-[AC_CHECK_TOOL(RANLIB, ranlib, :)])
-
-
-# Check for mawk first since it's generally faster.
-AC_DEFUN([AC_PROG_AWK],
-[AC_CHECK_PROGS(AWK, mawk gawk nawk awk, )])
-
-
-# AC_PROG_YACC
-# ------------
-AC_DEFUN([AC_PROG_YACC],
-[AC_CHECK_PROGS(YACC, 'bison -y' byacc, yacc)])
-
-
-# AC_PROG_LEX
-# -----------
-# Look for flex or lex. Set its associated library to LEXLIB.
-# Check if lex declares yytext as a char * by default, not a char[].
-AC_DEFUN_ONCE([AC_PROG_LEX],
-[AC_CHECK_PROGS(LEX, flex lex, :)
-if test -z "$LEXLIB"
-then
- AC_CHECK_LIB(fl, yywrap, LEXLIB="-lfl",
- [AC_CHECK_LIB(l, yywrap, LEXLIB="-ll")])
-fi
-AC_SUBST(LEXLIB)
-if test "x$LEX" != "x:"; then
- _AC_DECL_YYTEXT
-fi])
-
-
-# _AC_DECL_YYTEXT
-# ---------------
-# Check if lex declares yytext as a char * by default, not a char[].
-m4_define([_AC_DECL_YYTEXT],
-[AC_CACHE_CHECK(lex output file root, ac_cv_prog_lex_root,
-[# The minimal lex program is just a single line: %%. But some broken lexes
-# (Solaris, I think it was) want two %% lines, so accommodate them.
-echo '%%
-%%' | $LEX
-if test -f lex.yy.c; then
- ac_cv_prog_lex_root=lex.yy
-elif test -f lexyy.c; then
- ac_cv_prog_lex_root=lexyy
-else
- AC_MSG_ERROR([cannot find output from $LEX; giving up])
-fi])
-LEX_OUTPUT_ROOT=$ac_cv_prog_lex_root
-AC_SUBST(LEX_OUTPUT_ROOT)dnl
-
-AC_CACHE_CHECK(whether yytext is a pointer, ac_cv_prog_lex_yytext_pointer,
-[# POSIX says lex can declare yytext either as a pointer or an array; the
-# default is implementation-dependent. Figure out which it is, since
-# not all implementations provide the %pointer and %array declarations.
-ac_cv_prog_lex_yytext_pointer=no
-echo 'extern char *yytext;' >>$LEX_OUTPUT_ROOT.c
-ac_save_LIBS=$LIBS
-LIBS="$LIBS $LEXLIB"
-AC_LINK_IFELSE([`cat $LEX_OUTPUT_ROOT.c`], ac_cv_prog_lex_yytext_pointer=yes)
-LIBS=$ac_save_LIBS
-rm -f "${LEX_OUTPUT_ROOT}.c"
-])
-dnl
-if test $ac_cv_prog_lex_yytext_pointer = yes; then
- AC_DEFINE(YYTEXT_POINTER, 1,
- [Define if `lex' declares `yytext' as a `char *' by default,
- not a `char[]'.])
-fi
-])# _AC_DECL_YYTEXT
-
-
-# Require AC_PROG_LEX in case some people were just calling this macro.
-AU_DEFUN([AC_DECL_YYTEXT],
-[AC_PROG_LEX])
-
-
-# AC_PROG_INSTALL
-# ---------------
-AC_DEFUN([AC_PROG_INSTALL],
-[AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
-# Find a good install program. We prefer a C program (faster),
-# so one script is as good as another. But avoid the broken or
-# incompatible versions:
-# SysV /etc/install, /usr/sbin/install
-# SunOS /usr/etc/install
-# IRIX /sbin/install
-# AIX /bin/install
-# AmigaOS /C/install, which installs bootblocks on floppy discs
-# AIX 4 /usr/bin/installbsd, which doesn't work without a -g flag
-# AFS /usr/afsws/bin/install, which mishandles nonexistent args
-# SVR4 /usr/ucb/install, which tries to use the nonexistent group "staff"
-# ./install, which can be erroneously created by make from ./install.sh.
-AC_MSG_CHECKING([for a BSD compatible install])
-if test -z "$INSTALL"; then
-AC_CACHE_VAL(ac_cv_path_install,
-[ ac_save_IFS=$IFS; IFS=$ac_path_separator
- for ac_dir in $PATH; do
- IFS=$ac_save_IFS
- # Account for people who put trailing slashes in PATH elements.
- case $ac_dir/ in
- / | ./ | .// | /[cC]/* \
- | /etc/* | /usr/sbin/* | /usr/etc/* | /sbin/* | /usr/afsws/bin/* \
- | /usr/ucb/* ) ;;
- *)
- # OSF1 and SCO ODT 3.0 have their own names for install.
- # Don't use installbsd from OSF since it installs stuff as root
- # by default.
- for ac_prog in ginstall scoinst install; do
- if AS_EXECUTABLE_P(["$ac_dir/$ac_prog"]); then
- if test $ac_prog = install &&
- grep dspmsg "$ac_dir/$ac_prog" >/dev/null 2>&1; then
- # AIX install. It has an incompatible calling convention.
- :
- elif test $ac_prog = install &&
- grep pwplus "$ac_dir/$ac_prog" >/dev/null 2>&1; then
- # program-specific install script used by HP pwplus--don't use.
- :
- else
- ac_cv_path_install="$ac_dir/$ac_prog -c"
- break 2
- fi
- fi
- done
- ;;
- esac
- done
-])dnl
- if test "${ac_cv_path_install+set}" = set; then
- INSTALL=$ac_cv_path_install
- else
- # As a last resort, use the slow shell script. We don't cache a
- # path for INSTALL within a source directory, because that will
- # break other packages using the cache if that directory is
- # removed, or if the path is relative.
- INSTALL=$ac_install_sh
- fi
-fi
-dnl We do special magic for INSTALL instead of AC_SUBST, to get
-dnl relative paths right.
-AC_MSG_RESULT([$INSTALL])
-
-# Use test -z because SunOS4 sh mishandles braces in ${var-val}.
-# It thinks the first close brace ends the variable substitution.
-test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM='${INSTALL}'
-AC_SUBST(INSTALL_PROGRAM)dnl
-
-test -z "$INSTALL_SCRIPT" && INSTALL_SCRIPT='${INSTALL}'
-AC_SUBST(INSTALL_SCRIPT)dnl
-
-test -z "$INSTALL_DATA" && INSTALL_DATA='${INSTALL} -m 644'
-AC_SUBST(INSTALL_DATA)dnl
-])# AC_PROG_INSTALL
-
-
-# AC_PROG_LN_S
-# ------------
-AC_DEFUN([AC_PROG_LN_S],
-[AC_MSG_CHECKING([whether ln -s works])
-AC_SUBST([LN_S], [$as_ln_s])dnl
-if test "$LN_S" = "ln -s"; then
- AC_MSG_RESULT([yes])
-else
- AC_MSG_RESULT([no, using $LN_S])
-fi
-])# AC_PROG_LN_S
-
-
-# AC_RSH
-# ------
-# I don't know what it used to do, but it no longer does.
-AU_DEFUN([AC_RSH],
-[AC_DIAGNOSE([obsolete], [$0: is no longer supported.
-Remove this warning when you adjust the code.])])
-
## ------------------------- ##
Index: tests/Makefile.am
--- tests/Makefile.am Tue, 21 Aug 2001 10:28:25 +0200 akim
+++ tests/Makefile.am Tue, 21 Aug 2001 10:44:28 +0200 akim
@@ -23,7 +23,7 @@
SUITE_GENERATED = \
aclang.at acc.at acfortran.at \
acgeneral.at acspecific.at acfunctions.at acheaders.at actypes.at \
- aclibs.at
+ aclibs.at acprograms.at
SUITE = suite.at \
m4sugar.at m4sh.at \
@@ -67,7 +67,8 @@ testsuite: $(top_srcdir)/lib/m4sugar/m4s
$(top_srcdir)/lib/autoconf/fortran.m4 \
$(top_srcdir)/lib/autoconf/headers.m4 \
$(top_srcdir)/lib/autoconf/libs.m4 \
- $(top_srcdir)/lib/autoconf/types.m4
+ $(top_srcdir)/lib/autoconf/types.m4 \
+ $(top_srcdir)/lib/autoconf/programs.m4
$(SUITE_GENERATED): mktests.sh $(MACRO_FILES)
cd $(srcdir) && ./mktests.sh $(MACRO_FILES)
Index: tests/suite.at
--- tests/suite.at Tue, 21 Aug 2001 10:28:25 +0200 akim
+++ tests/suite.at Tue, 21 Aug 2001 10:37:12 +0200 akim
@@ -67,6 +67,7 @@
# for types requires looking for headers etc.
m4_include([acgeneral.at])
m4_include([acspecific.at])
+m4_include([acprograms.at])
m4_include([acheaders.at])
m4_include([actypes.at])
m4_include([acfunctions.at])
Index: lib/autoconf/programs.m4
--- 0.706/lib/autoconf/programs.m4 Tue, 21 Aug 2001 10:45:50 +0200 akim ()
+++ lib/autoconf/programs.m4 Tue, 21 Aug 2001 10:35:36 +0200 akim
@@ -0,0 +1,499 @@
+# This file is part of Autoconf. -*- Autoconf -*-
+# Checking for programs.
+# Copyright 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001
+# Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2, or (at your option)
+# any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
+# 02111-1307, USA.
+
+# As a special exception, the Free Software Foundation gives unlimited
+# permission to copy, distribute and modify the configure scripts that
+# are the output of Autoconf. You need not follow the terms of the GNU
+# General Public License when using or distributing such scripts, even
+# though portions of the text of Autoconf appear in them. The GNU
+# General Public License (GPL) does govern all other use of the material
+# that constitutes the Autoconf program.
+#
+# Certain portions of the Autoconf source text are designed to be copied
+# (in certain cases, depending on the input) into the output of
+# Autoconf. We call these the "data" portions. The rest of the Autoconf
+# source text consists of comments plus executable code that decides which
+# of the data portions to output in any given case. We call these
+# comments and executable code the "non-data" portions. Autoconf never
+# copies any of the non-data portions into its output.
+#
+# This special exception to the GPL applies to versions of Autoconf
+# released by the Free Software Foundation. When you make and
+# distribute a modified version of Autoconf, you may extend this special
+# exception to the GPL to apply to your modified version as well, *unless*
+# your modified version has the potential to copy into its output some
+# of the text that was the non-data portion of the version that you started
+# with. (In other words, unless your change moves or copies text from
+# the non-data portions to the data portions.) If your modification has
+# such potential, you must delete any notice of this special exception
+# to the GPL from your modified version.
+#
+# Written by David MacKenzie, with help from
+# Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
+# Roland McGrath, Noah Friedman, david d zuhn, and many others.
+
+
+## ----------------------------- ##
+## Generic checks for programs. ##
+## ----------------------------- ##
+
+
+# AC_SHELL_PATH_WALK([PATH = $PATH], BODY)
+# ----------------------------------------
+# Walk through PATH running BODY for each `ac_dir'.
+#
+# `$ac_dummy' forces splitting on constant user-supplied paths.
+# POSIX.2 word splitting is done only on the output of word
+# expansions, not every word. This closes a longstanding sh security
+# hole.
+m4_define([AC_SHELL_PATH_WALK],
+[ac_save_IFS=$IFS; IFS=$ac_path_separator
+ac_dummy="m4_default([$1], [$PATH])"
+for ac_dir in $ac_dummy; do
+ IFS=$ac_save_IFS
+ test -z "$ac_dir" && ac_dir=.
+ $2
+done
+])
+
+
+# AC_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
+# [VALUE-IF-FOUND], [VALUE-IF-NOT-FOUND],
+# [PATH], [REJECT])
+# -----------------------------------------------------
+AC_DEFUN([AC_CHECK_PROG],
+[# Extract the first word of "$2", so it can be a program name with args.
+set dummy $2; ac_word=$[2]
+AC_MSG_CHECKING([for $ac_word])
+AC_CACHE_VAL(ac_cv_prog_$1,
+[if test -n "$$1"; then
+ ac_cv_prog_$1="$$1" # Let the user override the test.
+else
+m4_ifvaln([$6],
+[ ac_prog_rejected=no])dnl
+ AC_SHELL_PATH_WALK([$5],
+[AS_EXECUTABLE_P("$ac_dir/$ac_word") || continue
+m4_ifvaln([$6],
+[if test "$ac_dir/$ac_word" = "$6"; then
+ ac_prog_rejected=yes
+ continue
+fi])dnl
+ac_cv_prog_$1="$3"
+echo "$as_me:__oline__: found $ac_dir/$ac_word" >&AS_MESSAGE_LOG_FD
+break])
+m4_ifvaln([$6],
+[if test $ac_prog_rejected = yes; then
+ # We found a bogon in the path, so make sure we never use it.
+ set dummy $ac_cv_prog_$1
+ shift
+ if test address@hidden:@] != 0; then
+ # We chose a different compiler from the bogus one.
+ # However, it has the same basename, so the bogon will be chosen
+ # first if we set $1 to just the basename; use the full file name.
+ shift
+ set dummy "$ac_dir/$ac_word" ${1+"address@hidden"}
+ shift
+ ac_cv_prog_$1="address@hidden"
+m4_if([$2], [$4],
+[ else
+ # Default is a loser.
+ AC_MSG_ERROR([$1=$6 unacceptable, but no other $4 found in dnl
+m4_default([$5], [\$PATH])])
+])dnl
+ fi
+fi])dnl
+dnl If no 4th arg is given, leave the cache variable unset,
+dnl so AC_CHECK_PROGS will keep looking.
+m4_ifvaln([$4],
+[ test -z "$ac_cv_prog_$1" && ac_cv_prog_$1="$4"])dnl
+fi])dnl
+$1=$ac_cv_prog_$1
+if test -n "$$1"; then
+ AC_MSG_RESULT([$$1])
+else
+ AC_MSG_RESULT([no])
+fi
+AC_SUBST($1)dnl
+])# AC_CHECK_PROG
+
+
+# AC_CHECK_PROGS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
+# [PATH])
+# ------------------------------------------------------------------
+AC_DEFUN([AC_CHECK_PROGS],
+[for ac_prog in $2
+do
+ AC_CHECK_PROG([$1], [$ac_prog], [$ac_prog], , [$4])
+ test -n "$$1" && break
+done
+m4_ifvaln([$3], [test -n "$$1" || $1="$3"])])
+
+
+# AC_PATH_PROG(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
+# -----------------------------------------------------------------------
+AC_DEFUN([AC_PATH_PROG],
+[# Extract the first word of "$2", so it can be a program name with args.
+set dummy $2; ac_word=$[2]
+AC_MSG_CHECKING([for $ac_word])
+AC_CACHE_VAL([ac_cv_path_$1],
+[case $$1 in
+ [[\\/]]* | ?:[[\\/]]*)
+ ac_cv_path_$1="$$1" # Let the user override the test with a path.
+ ;;
+ *)
+ AC_SHELL_PATH_WALK([$4],
+[if AS_EXECUTABLE_P("$ac_dir/$ac_word"); then
+ ac_cv_path_$1="$ac_dir/$ac_word"
+ echo "$as_me:__oline__: found $ac_dir/$ac_word" >&AS_MESSAGE_LOG_FD
+ break
+fi])
+dnl If no 3rd arg is given, leave the cache variable unset,
+dnl so AC_PATH_PROGS will keep looking.
+m4_ifvaln([$3],
+[ test -z "$ac_cv_path_$1" && ac_cv_path_$1="$3"])dnl
+ ;;
+esac])dnl
+AC_SUBST([$1], [$ac_cv_path_$1])
+if test -n "$$1"; then
+ AC_MSG_RESULT([$$1])
+else
+ AC_MSG_RESULT([no])
+fi
+])# AC_PATH_PROG
+
+
+# AC_PATH_PROGS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
+# [PATH])
+# -----------------------------------------------------------------
+AC_DEFUN([AC_PATH_PROGS],
+[for ac_prog in $2
+do
+ AC_PATH_PROG([$1], [$ac_prog], , [$4])
+ test -n "$$1" && break
+done
+m4_ifvaln([$3], [test -n "$$1" || $1="$3"])dnl
+])
+
+
+
+
+## -------------------------- ##
+## Generic checks for tools. ##
+## -------------------------- ##
+
+
+# AC_CHECK_TOOL_PREFIX
+# --------------------
+AU_DEFUN([AC_CHECK_TOOL_PREFIX])
+
+
+# AC_PATH_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
+# -----------------------------------------------------------------------
+# (Use different variables $1 and ac_pt_$1 so that cache vars don't conflict.)
+AC_DEFUN([AC_PATH_TOOL],
+[if test -n "$ac_tool_prefix"; then
+ AC_PATH_PROG([$1], [${ac_tool_prefix}$2], , [$4])
+fi
+if test -z "$ac_cv_path_$1"; then
+ ac_pt_$1=$$1
+ AC_PATH_PROG([ac_pt_$1], [$2], [$3], [$4])
+ $1=$ac_pt_$1
+else
+ $1="$ac_cv_path_$1"
+fi
+])# AC_PATH_TOOL
+
+
+# AC_CHECK_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
+# ------------------------------------------------------------------------
+# (Use different variables $1 and ac_ct_$1 so that cache vars don't conflict.)
+AC_DEFUN([AC_CHECK_TOOL],
+[if test -n "$ac_tool_prefix"; then
+ AC_CHECK_PROG([$1], [${ac_tool_prefix}$2], [${ac_tool_prefix}$2], , [$4])
+fi
+if test -z "$ac_cv_prog_$1"; then
+ ac_ct_$1=$$1
+ AC_CHECK_PROG([ac_ct_$1], [$2], [$2], [$3], [$4])
+ $1=$ac_ct_$1
+else
+ $1="$ac_cv_prog_$1"
+fi
+])# AC_CHECK_TOOL
+
+
+# AC_CHECK_TOOLS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND],
+# [PATH])
+# ------------------------------------------------------------------
+# Check for each tool in PROGS-TO-CHECK-FOR with the cross prefix. If
+# none can be found with a cross prefix, then use the first one that
+# was found without the cross prefix.
+AC_DEFUN([AC_CHECK_TOOLS],
+[if test -n "$ac_tool_prefix"; then
+ for ac_prog in $2
+ do
+ AC_CHECK_PROG([$1],
+ [$ac_tool_prefix$ac_prog], [$ac_tool_prefix$ac_prog],,
+ [$4])
+ test -n "$$1" && break
+ done
+fi
+if test -z "$$1"; then
+ ac_ct_$1=$$1
+ AC_CHECK_PROGS([ac_ct_$1], [$2], [$3], [$4])
+ $1=$ac_ct_$1
+fi
+])# AC_CHECK_TOOLS
+
+
+
+## ---------------- ##
+## Specific tests. ##
+## ---------------- ##
+
+# Please, keep this section sorted.
+# (But of course when keeping related things together).
+
+# Check for mawk first since it's generally faster.
+AC_DEFUN([AC_PROG_AWK],
+[AC_CHECK_PROGS(AWK, mawk gawk nawk awk, )])
+
+
+# _AC_PROG_ECHO
+# -------------
+# Check whether to use -n, \c, or newline-tab to separate
+# checking messages from result messages.
+# Don't try to cache, since the results of this macro are needed to
+# display the checking message. In addition, caching something used once
+# has little interest.
+# Idea borrowed from dist 3.0. Use `*c*,', not `*c,' because if `\c'
+# failed there is also a new-line to match.
+m4_define([_AC_PROG_ECHO],
+[case `echo "testing\c"; echo 1,2,3`,`echo -n testing; echo 1,2,3` in
+ *c*,-n*) ECHO_N= ECHO_C='
+' ECHO_T=' ' ;;
+ *c*,* ) ECHO_N=-n ECHO_C= ECHO_T= ;;
+ *) ECHO_N= ECHO_C='\c' ECHO_T= ;;
+esac
+AC_SUBST(ECHO_C)dnl
+AC_SUBST(ECHO_N)dnl
+AC_SUBST(ECHO_T)dnl
+])# _AC_PROG_ECHO
+
+
+# AC_PROG_INSTALL
+# ---------------
+AC_DEFUN([AC_PROG_INSTALL],
+[AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
+# Find a good install program. We prefer a C program (faster),
+# so one script is as good as another. But avoid the broken or
+# incompatible versions:
+# SysV /etc/install, /usr/sbin/install
+# SunOS /usr/etc/install
+# IRIX /sbin/install
+# AIX /bin/install
+# AmigaOS /C/install, which installs bootblocks on floppy discs
+# AIX 4 /usr/bin/installbsd, which doesn't work without a -g flag
+# AFS /usr/afsws/bin/install, which mishandles nonexistent args
+# SVR4 /usr/ucb/install, which tries to use the nonexistent group "staff"
+# ./install, which can be erroneously created by make from ./install.sh.
+AC_MSG_CHECKING([for a BSD compatible install])
+if test -z "$INSTALL"; then
+AC_CACHE_VAL(ac_cv_path_install,
+[ ac_save_IFS=$IFS; IFS=$ac_path_separator
+ for ac_dir in $PATH; do
+ IFS=$ac_save_IFS
+ # Account for people who put trailing slashes in PATH elements.
+ case $ac_dir/ in
+ / | ./ | .// | /[cC]/* \
+ | /etc/* | /usr/sbin/* | /usr/etc/* | /sbin/* | /usr/afsws/bin/* \
+ | /usr/ucb/* ) ;;
+ *)
+ # OSF1 and SCO ODT 3.0 have their own names for install.
+ # Don't use installbsd from OSF since it installs stuff as root
+ # by default.
+ for ac_prog in ginstall scoinst install; do
+ if AS_EXECUTABLE_P(["$ac_dir/$ac_prog"]); then
+ if test $ac_prog = install &&
+ grep dspmsg "$ac_dir/$ac_prog" >/dev/null 2>&1; then
+ # AIX install. It has an incompatible calling convention.
+ :
+ elif test $ac_prog = install &&
+ grep pwplus "$ac_dir/$ac_prog" >/dev/null 2>&1; then
+ # program-specific install script used by HP pwplus--don't use.
+ :
+ else
+ ac_cv_path_install="$ac_dir/$ac_prog -c"
+ break 2
+ fi
+ fi
+ done
+ ;;
+ esac
+ done
+])dnl
+ if test "${ac_cv_path_install+set}" = set; then
+ INSTALL=$ac_cv_path_install
+ else
+ # As a last resort, use the slow shell script. We don't cache a
+ # path for INSTALL within a source directory, because that will
+ # break other packages using the cache if that directory is
+ # removed, or if the path is relative.
+ INSTALL=$ac_install_sh
+ fi
+fi
+dnl We do special magic for INSTALL instead of AC_SUBST, to get
+dnl relative paths right.
+AC_MSG_RESULT([$INSTALL])
+
+# Use test -z because SunOS4 sh mishandles braces in ${var-val}.
+# It thinks the first close brace ends the variable substitution.
+test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM='${INSTALL}'
+AC_SUBST(INSTALL_PROGRAM)dnl
+
+test -z "$INSTALL_SCRIPT" && INSTALL_SCRIPT='${INSTALL}'
+AC_SUBST(INSTALL_SCRIPT)dnl
+
+test -z "$INSTALL_DATA" && INSTALL_DATA='${INSTALL} -m 644'
+AC_SUBST(INSTALL_DATA)dnl
+])# AC_PROG_INSTALL
+
+
+# AC_PROG_LEX
+# -----------
+# Look for flex or lex. Set its associated library to LEXLIB.
+# Check if lex declares yytext as a char * by default, not a char[].
+AC_DEFUN_ONCE([AC_PROG_LEX],
+[AC_CHECK_PROGS(LEX, flex lex, :)
+if test -z "$LEXLIB"
+then
+ AC_CHECK_LIB(fl, yywrap, LEXLIB="-lfl",
+ [AC_CHECK_LIB(l, yywrap, LEXLIB="-ll")])
+fi
+AC_SUBST(LEXLIB)
+if test "x$LEX" != "x:"; then
+ _AC_PROG_LEX_YYTEXT_DECL
+fi])
+
+
+# _AC_PROG_LEX_YYTEXT_DECL
+# ------------------------
+# Check if lex declares yytext as a char * by default, not a char[].
+m4_define([_AC_PROG_LEX_YYTEXT_DECL],
+[AC_CACHE_CHECK(lex output file root, ac_cv_prog_lex_root,
+[# The minimal lex program is just a single line: %%. But some broken lexes
+# (Solaris, I think it was) want two %% lines, so accommodate them.
+echo '%%
+%%' | $LEX
+if test -f lex.yy.c; then
+ ac_cv_prog_lex_root=lex.yy
+elif test -f lexyy.c; then
+ ac_cv_prog_lex_root=lexyy
+else
+ AC_MSG_ERROR([cannot find output from $LEX; giving up])
+fi])
+LEX_OUTPUT_ROOT=$ac_cv_prog_lex_root
+AC_SUBST(LEX_OUTPUT_ROOT)dnl
+
+AC_CACHE_CHECK(whether yytext is a pointer, ac_cv_prog_lex_yytext_pointer,
+[# POSIX says lex can declare yytext either as a pointer or an array; the
+# default is implementation-dependent. Figure out which it is, since
+# not all implementations provide the %pointer and %array declarations.
+ac_cv_prog_lex_yytext_pointer=no
+echo 'extern char *yytext;' >>$LEX_OUTPUT_ROOT.c
+ac_save_LIBS=$LIBS
+LIBS="$LIBS $LEXLIB"
+AC_LINK_IFELSE([`cat $LEX_OUTPUT_ROOT.c`], ac_cv_prog_lex_yytext_pointer=yes)
+LIBS=$ac_save_LIBS
+rm -f "${LEX_OUTPUT_ROOT}.c"
+])
+dnl
+if test $ac_cv_prog_lex_yytext_pointer = yes; then
+ AC_DEFINE(YYTEXT_POINTER, 1,
+ [Define if `lex' declares `yytext' as a `char *' by default,
+ not a `char[]'.])
+fi
+])# _AC_PROG_LEX_YYTEXT_DECL
+
+
+# Require AC_PROG_LEX in case some people were just calling this macro.
+AU_DEFUN([AC_DECL_YYTEXT], [_AC_PROG_LEX_YYTEXT_DECL])
+
+
+# AC_PROG_LN_S
+# ------------
+AC_DEFUN([AC_PROG_LN_S],
+[AC_MSG_CHECKING([whether ln -s works])
+AC_SUBST([LN_S], [$as_ln_s])dnl
+if test "$LN_S" = "ln -s"; then
+ AC_MSG_RESULT([yes])
+else
+ AC_MSG_RESULT([no, using $LN_S])
+fi
+])# AC_PROG_LN_S
+
+
+# AC_PROG_MAKE_SET
+# ----------------
+# Define SET_MAKE to set ${MAKE} if make doesn't.
+AC_DEFUN([AC_PROG_MAKE_SET],
+[AC_MSG_CHECKING([whether ${MAKE-make} sets \${MAKE}])
+set dummy ${MAKE-make}; ac_make=`echo "$[2]" | sed 'y,./+-,__p_,'`
+AC_CACHE_VAL(ac_cv_prog_make_${ac_make}_set,
+[cat >conftest.make <<\_ACEOF
+all:
+ @echo 'ac_maketemp="${MAKE}"'
+_ACEOF
+# GNU make sometimes prints "make[1]: Entering...", which would confuse us.
+eval `${MAKE-make} -f conftest.make 2>/dev/null | grep temp=`
+if test -n "$ac_maketemp"; then
+ eval ac_cv_prog_make_${ac_make}_set=yes
+else
+ eval ac_cv_prog_make_${ac_make}_set=no
+fi
+rm -f conftest.make])dnl
+if eval "test \"`echo '$ac_cv_prog_make_'${ac_make}_set`\" = yes"; then
+ AC_MSG_RESULT([yes])
+ SET_MAKE=
+else
+ AC_MSG_RESULT([no])
+ SET_MAKE="MAKE=${MAKE-make}"
+fi
+AC_SUBST([SET_MAKE])dnl
+])# AC_PROG_MAKE_SET
+
+
+# AC_PROG_RANLIB
+# --------------
+AC_DEFUN([AC_PROG_RANLIB],
+[AC_CHECK_TOOL(RANLIB, ranlib, :)])
+
+
+# AC_RSH
+# ------
+# I don't know what it used to do, but it no longer does.
+AU_DEFUN([AC_RSH],
+[AC_DIAGNOSE([obsolete], [$0: is no longer supported.
+Remove this warning when you adjust the code.])])
+
+
+# AC_PROG_YACC
+# ------------
+AC_DEFUN([AC_PROG_YACC],
+[AC_CHECK_PROGS(YACC, 'bison -y' byacc, yacc)])
| [Prev in Thread] |
Current Thread |
[Next in Thread] |
- 43-autoconf-programs.patch,
Akim Demaille <=