[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[dhcp] 02/02: Add autotools framework; rename 'Makefile' to 'Makefile.ol
From: |
Ludovic Courtès |
Subject: |
[dhcp] 02/02: Add autotools framework; rename 'Makefile' to 'Makefile.old'. |
Date: |
Fri, 12 Jun 2015 08:19:42 +0000 |
civodul pushed a commit to branch master
in repository dhcp.
commit d1865d0e617ea846bf5cc9d53389530586852311
Author: Ludovic Courtès <address@hidden>
Date: Fri Jun 12 10:19:17 2015 +0200
Add autotools framework; rename 'Makefile' to 'Makefile.old'.
---
.gitignore | 10 ++++++
Makefile.am | 69 ++++++++++++++++++++++++++++++++++++++++++++++
Makefile => Makefile.old | 0
configure.ac | 38 +++++++++++++++++++++++++
pre-inst-env.in | 39 ++++++++++++++++++++++++++
5 files changed, 156 insertions(+), 0 deletions(-)
diff --git a/.gitignore b/.gitignore
index b1dbeb2..cb66e02 100644
--- a/.gitignore
+++ b/.gitignore
@@ -1,2 +1,12 @@
libinterfaces.so
*.log
+/INSTALL
+*~
+Makefile.in
+/aclocal.m4
+/autom4te.cache/
+/build-aux/
+/config.cache
+/config.status
+/configure
+/pre-inst-env
diff --git a/Makefile.am b/Makefile.am
new file mode 100644
index 0000000..b2106f3
--- /dev/null
+++ b/Makefile.am
@@ -0,0 +1,69 @@
+# GNU DHCP --- DHCP client.
+# Copyright © 2015 Ludovic Courtès <address@hidden>
+#
+# This file is part of GNU DHCP.
+#
+# GNU DHCP is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or (at
+# your option) any later version.
+#
+# GNU DHCP is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with GNU DHCP. If not, see <http://www.gnu.org/licenses/>.
+
+MODULES = \
+ dhcp/dhcp.scm \
+ dhcp/options/names.scm \
+ dhcp/options/base.scm \
+ dhcp/messages.scm \
+ dhcp/client.scm \
+ dhcp/interfaces.scm \
+ dhcp/send.scm \
+ arp/messages.scm \
+ arp/identifiers.scm
+
+GOBJECTS = $(MODULES:%.scm=%.go)
+
+nobase_dist_guilemodule_DATA = $(MODULES)
+nobase_nodist_guilemodule_DATA = $(GOBJECTS)
+
+# TODO: Handle tests.
+
+
+AM_V_GUILEC = $(AM_V_GUILEC_$(V))
+AM_V_GUILEC_ = $(AM_V_GUILEC_$(AM_DEFAULT_VERBOSITY))
+AM_V_GUILEC_0 = @echo " GUILEC" $@;
+
+# Unset 'GUILE_LOAD_COMPILED_PATH' altogether while compiling. Otherwise, if
+# $GUILE_LOAD_COMPILED_PATH contains $(moduledir), we may find .go files in
+# there that are newer than the local .scm files (for instance because the
+# user ran 'make install' recently). When that happens, we end up loading
+# those previously-installed .go files, which may be stale, thereby breaking
+# the whole thing.
+#
+# XXX: Use the C locale for when Guile lacks
+#
<http://git.sv.gnu.org/cgit/guile.git/commit/?h=stable-2.0&id=e2c6bf3866d1186c60bacfbd4fe5037087ee5e3f>.
+.scm.go:
+ $(AM_V_GUILEC)$(MKDIR_P) `dirname "$@"` ; \
+ unset GUILE_LOAD_COMPILED_PATH ; \
+ LC_ALL=C \
+ $(top_builddir)/pre-inst-env \
+ $(GUILD) compile -L "$(top_builddir)" -L "$(top_srcdir)" \
+ -Wformat -Wunbound-variable -Warity-mismatch \
+ --target="$(host)" \
+ -o "$@" "$<"
+
+SUFFIXES = .go
+
+# Make sure source files are installed first, so that the mtime of
+# installed compiled files is greater than that of installed source
+# files. See
+# <http://lists.gnu.org/archive/html/guile-devel/2010-07/msg00125.html>
+# for details.
+guix_install_go_files = install-nobase_nodist_guilemoduleDATA
+$(guix_install_go_files): install-nobase_dist_guilemoduleDATA
diff --git a/Makefile b/Makefile.old
similarity index 100%
rename from Makefile
rename to Makefile.old
diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..89913d1
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,38 @@
+# -*- Autoconf -*-
+# Process this file with autoconf to produce a configure script.
+
+AC_PREREQ(2.69)
+AC_INIT([GNU DHCP], [0.0], address@hidden, [guix],
+ [http://www.gnu.org/software/guix/])
+AC_CONFIG_AUX_DIR([build-aux])
+
+AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
+ color-tests parallel-tests -Woverride -Wno-portability])
+
+# Enable silent rules by default.
+AM_SILENT_RULES([yes])
+
+AC_CONFIG_SRCDIR([dhcp/dhcp.scm])
+AC_CONFIG_MACRO_DIR([m4])
+
+AC_CANONICAL_HOST
+
+dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
+dnl Make sure they are available.
+m4_pattern_forbid([PKG_CHECK_MODULES])
+m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
+
+PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
+AC_PATH_PROG([GUILE], [guile])
+AC_PATH_PROG([GUILD], [guild])
+if test "x$GUILD" = "x"; then
+ AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x
installation.])
+fi
+
+guilemoduledir="${datarootdir}/guile/site/2.0"
+AC_SUBST([guilemoduledir])
+
+AC_CONFIG_FILES([Makefile])
+AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
+
+AC_OUTPUT
diff --git a/pre-inst-env.in b/pre-inst-env.in
new file mode 100644
index 0000000..8995ba1
--- /dev/null
+++ b/pre-inst-env.in
@@ -0,0 +1,39 @@
+#!/bin/sh
+
+# DHCP --- DHCP client.
+# Copyright © 2012, 2013, 2014, 2015 Ludovic Courtès <address@hidden>
+#
+# This file is part of GNU DHCP.
+#
+# GNU DHCP is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or (at
+# your option) any later version.
+#
+# GNU DHCP is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with GNU DHCP. If not, see <http://www.gnu.org/licenses/>.
+
+# Usage: ./pre-inst-env COMMAND ARG...
+#
+# Run COMMAND in a pre-installation environment. Typical use is
+# "./pre-inst-env guile".
+
+# By default we may end up with absolute directory names that contain '..',
+# which get into $GUILE_LOAD_PATH, leading to '..' in the module file names
+# recorded by Guile. To avoid that, make sure we get a real absolute
+# directory name. Additionally, use '-P' to get the canonical directory name
+# so that Guile's 'relative' %file-port-name-canonicalization can actually
+# work (see <http://bugs.gnu.org/17935>.)
+abs_top_srcdir="`cd "@abs_top_srcdir@" > /dev/null; pwd -P`"
+abs_top_builddir="`cd "@abs_top_builddir@" > /dev/null; pwd -P`"
+
+GUILE_LOAD_COMPILED_PATH="$abs_top_builddir${GUILE_LOAD_COMPILED_PATH:+:}$GUILE_LOAD_COMPILED_PATH"
+GUILE_LOAD_PATH="$abs_top_builddir:$abs_top_srcdir${GUILE_LOAD_PATH:+:}$GUILE_LOAD_PATH"
+export GUILE_LOAD_COMPILED_PATH GUILE_LOAD_PATH
+
+exec "$@"