[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
bug#59486: completion-auto-wrap disobeyed by vertical navigation
From: |
Juri Linkov |
Subject: |
bug#59486: completion-auto-wrap disobeyed by vertical navigation |
Date: |
Tue, 22 Nov 2022 19:38:57 +0200 |
User-agent: |
Gnus/5.13 (Gnus v5.13) Emacs/29.0.50 (x86_64-pc-linux-gnu) |
In a multi-column layout, the keys <left> and <right>
wrap to the beginning/end of the completions buffer,
but <up> and <down> don't. Here is a patch that supports
completion-auto-wrap for wrapping to the top/bottom:
diff --git a/lisp/simple.el b/lisp/simple.el
index 0f44b14948c..459af2fcf55 100644
--- a/lisp/simple.el
+++ b/lisp/simple.el
@@ -9572,6 +9574,8 @@ completion-list-mode-map
(define-key map "\C-m" 'choose-completion)
(define-key map "\e\e\e" 'delete-completion-window)
(define-key map [remap keyboard-quit] #'delete-completion-window)
+ (define-key map [up] 'previous-line-completion)
+ (define-key map [down] 'next-line-completion)
(define-key map [left] 'previous-completion)
(define-key map [right] 'next-completion)
(define-key map [?\t] 'next-completion)
@@ -9736,6 +9740,77 @@ next-completion
(when (/= 0 n)
(switch-to-minibuffer))))
+(defun previous-line-completion (&optional n)
+ "Move to the item on the previous line in the completion list.
+With prefix argument N, move back N items line-wise (negative N
+means move forward).
+
+Also see the `completion-auto-wrap' variable."
+ (interactive "p")
+ (next-line-completion (- n)))
+
+(defun next-line-completion (&optional n)
+ "Move to the item on the next line in the completion list.
+With prefix argument N, move N items line-wise (negative N
+means move backward).
+
+Also see the `completion-auto-wrap' variable."
+ (interactive "p")
+ (let ((column (current-column))
+ pos)
+ (catch 'bound
+ (while (> n 0)
+ (setq pos nil)
+ (save-excursion
+ (while (and (not pos) (not (eobp)))
+ (forward-line 1)
+ (when (and (not (eobp))
+ (eq (move-to-column column) column)
+ (get-text-property (point) 'mouse-face))
+ (setq pos (point)))))
+ (if pos
+ (goto-char pos)
+ (when completion-auto-wrap
+ (let ((column (current-column)))
+ (save-excursion
+ (goto-char (point-min))
+ (when (and (eq (move-to-column column) column)
+ (get-text-property (point) 'mouse-face))
+ (setq pos (point)))
+ (while (and (not pos) (not (eobp)))
+ (forward-line 1)
+ (when (and (eq (move-to-column column) column)
+ (get-text-property (point) 'mouse-face))
+ (setq pos (point)))))
+ (if pos (goto-char pos)))))
+ (setq n (1- n)))
+
+ (while (< n 0)
+ (setq pos nil)
+ (save-excursion
+ (while (and (not pos) (not (bobp)))
+ (forward-line -1)
+ (when (and (not (bobp))
+ (eq (move-to-column column) column)
+ (get-text-property (point) 'mouse-face))
+ (setq pos (point)))))
+ (if pos
+ (goto-char pos)
+ (when completion-auto-wrap
+ (let ((column (current-column)))
+ (save-excursion
+ (goto-char (point-max))
+ (when (and (eq (move-to-column column) column)
+ (get-text-property (point) 'mouse-face))
+ (setq pos (point)))
+ (while (and (not pos) (not (bobp)))
+ (forward-line -1)
+ (when (and (eq (move-to-column column) column)
+ (get-text-property (point) 'mouse-face))
+ (setq pos (point)))))
+ (if pos (goto-char pos)))))
+ (setq n (1+ n))))))
+
(defun choose-completion (&optional event no-exit no-quit)
"Choose the completion at point.
If EVENT, use EVENT's position to determine the starting position.
- bug#59486: completion-auto-wrap disobeyed by vertical navigation,
Juri Linkov <=
- bug#59486: completion-auto-wrap disobeyed by vertical navigation, Juri Linkov, 2022/11/23
- bug#59486: completion-auto-wrap disobeyed by vertical navigation, Juri Linkov, 2022/11/24
- bug#59486: completion-auto-wrap disobeyed by vertical navigation, Eli Zaretskii, 2022/11/24
- bug#59486: completion-auto-wrap disobeyed by vertical navigation, Juri Linkov, 2022/11/24
- bug#59486: completion-auto-wrap disobeyed by vertical navigation, Eli Zaretskii, 2022/11/24
- bug#59486: completion-auto-wrap disobeyed by vertical navigation, Juri Linkov, 2022/11/25
- bug#59486: completion-auto-wrap disobeyed by vertical navigation, Eli Zaretskii, 2022/11/25
- bug#59486: completion-auto-wrap disobeyed by vertical navigation, Juri Linkov, 2022/11/28